blob: 4bf70ab328fe10bf4eca25ddbf6f7ffaa6127f65 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# flashimg/cpu_main/CMakeLists.txt - Build script for main cpu_main.uf2 firmware file
#
# Copyright (C) 2024-2025 Luke T. Shumaker <lukeshu@lukeshu.com>
# SPDX-License-Identifier: AGPL-3.0-or-later
if (PICO_PLATFORM STREQUAL "rp2040")
# Compile ######################################################################
add_library(cpu_main_objs OBJECT
main.c
usb_keyboard.c
tusb_log.c
fs_harness_flash_bin.c
fs_harness_uptime_txt.c
flash_static.c
flashio.c
ihex.c
)
target_include_directories(cpu_main_objs PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/config)
target_include_directories(cpu_main_objs PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
target_include_directories(cpu_main_objs PRIVATE ${CMAKE_CURRENT_BINARY_DIR})
target_link_libraries(cpu_main_objs
pico_runtime
hardware_flash
hardware_uart
hardware_watchdog
libmisc
libusb
libdhcp
libhw_cr
lib9p_srv
lib9p_util
)
pico_minimize_runtime(cpu_main_objs
INCLUDE PANIC
)
target_compile_definitions(cpu_main_objs PRIVATE
PICO_PANIC_FUNCTION=assert_panic
#PICO_USE_FASTEST_SUPPORTED_CLOCK=1
# Calculated by `./3rd-party/pico-sdk/src/rp2_common/hardware_clocks/scripts/vcocalc.py --cmake-only 170`
PLL_SYS_REFDIV=2
PLL_SYS_VCO_FREQ_HZ=1530000000
PLL_SYS_POSTDIV1=3
PLL_SYS_POSTDIV2=3
SYS_CLK_HZ=170000000
)
suppress_tinyusb_warnings()
set_source_files_properties(
${PICO_SDK_PATH}/src/rp2_common/pico_clib_interface/newlib_interface.c
PROPERTIES
COMPILE_OPTIONS "-Wno-unused-parameter")
# Analyze the stack ############################################################
add_stack_analysis(stack.c cpu_main_objs)
# Link #########################################################################
add_executable(cpu_main)
target_include_directories(cpu_main PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/config)
target_sources(cpu_main PRIVATE
stack.c
"$<TARGET_OBJECTS:cpu_main_objs>"
)
target_link_libraries(cpu_main
pico_standard_link
)
target_link_options(cpu_main PRIVATE "$<TARGET_PROPERTY:cpu_main_objs,LINK_OPTIONS>")
pico_add_extra_outputs(cpu_main) # create .map/.bin/.hex/.uf2 files in addition to .elf
pico_set_program_url(cpu_main "https://git.lukeshu.com/sbc-harness")
# Embed ########################################################################
target_embed_sources(cpu_main_objs cpu_main static.h
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS.md
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS/agpl-3.0.txt
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS/dhcp.bsd3-mit.txt
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS/newlib.txt
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS/pico-sdk.bsd3.txt
static/Documentation/YOUR_RIGHTS_AND_OBLIGATIONS/tinyusb.mit.txt
static/Documentation/harness_rom.bin.txt
static/Documentation/harness_flash.bin.txt
static/Documentation/harness_uptime.txt.txt
)
endif()
# Tests ########################################################################
if ((PICO_PLATFORM STREQUAL "host") AND (ENABLE_TESTS))
add_executable(test_ihex "tests/test_ihex.c" "ihex.c")
target_include_directories(test_ihex PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/tests)
target_link_libraries(test_ihex
libhw_generic
)
add_test(
NAME "flashimg/cpu_main/test_ihex"
COMMAND "${CMAKE_SOURCE_DIR}/build-aux/valgrind" "./test_ihex"
)
endif()
|
