summaryrefslogtreecommitdiff
path: root/~fauno/pandoc/PKGBUILD
blob: d3b88d3a00518a61f38b25ef6d735de9284ed506 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
# Maintainer: Nicolas Reynolds <fauno@kiwwwi.com.ar>
# Based on haskell-pandoc

# Run `makepkg -srp SRCBUILD` if you want to update the source tarball

pkgname=pandoc
pkgver=1.9.4.5
pkgrel=3
pkgdesc='Conversion between markup formats (no Haskell libs)'
url='http://johnmacfarlane.net/pandoc/'
license=('GPL')
arch=('i686' 'x86_64')
makedepends=('ghc' 'sh' 'cabal-install')
options=(strip !makeflags !distcc)
source=(https://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}-$pkgrel-any.src.tar.xz{,.sig} SRCBUILD)
conflicts=('haskell-pandoc')
optdepends=('texlive-most: for pdf creation')

# PKGBUILD functions
build() {
    mkdir -p ${srcdir}/{build,${pkgname}-${pkgver}}
    cd ${srcdir}/${pkgname}-${pkgver}

   while read _hkpkg; do
       pushd ${srcdir}/${pkgname}-${pkgver}/${_hkpkg} >/dev/null

       extra="--prefix=${srcdir}/build/usr"
       case $_hkpkg in
        $pkgname-$pkgver)
          extra="--flags=\"executable -library\" --prefix=/usr --libdir=${srcdir}/build/usr/lib -v" ;;
        citeproc-hs-*)
          extra="--flags=\"embed_data_files\" --prefix=${srcdir}/build/usr -v" ;;
       esac

       msg2 "Configuring $_hkpkg with $extra"
       if [ "$_hkpkg" != "$pkgname-$pkgver" ]; then
         HOME=${srcdir}/${pkgname}-${pkgver} \
         cabal install $extra
       else 
         HOME=${srcdir}/${pkgname}-${pkgver} \
         cabal configure $extra
         HOME=${srcdir}/${pkgname}-${pkgver} \
         cabal build
       fi

       popd >/dev/null
   done <BUILDORDER

}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}/${pkgname}-${pkgver}

  runghc Setup.hs copy --destdir=${pkgdir}/

  msg2 "Removing lib files..."
  rm -rfv ${pkgdir}/build

# EC is unfree and makes Parabola TeXLive cry
# besides, it's unneeded
  sed "/fontenc/d" -i ${pkgdir}/usr/share/${pkgname}-${pkgver}/templates/default.latex

  find ${pkgdir}/usr/share -type f -exec chmod 644 {} \;
  find ${pkgdir}/usr/share -type d -exec chmod 755 {} \;
}
md5sums=('912abc4574aea3c5203eff1b02ceafa9'
         '7ac798d62f253535a2e194af5aa1c3c3'
         'e632f8c06be8284e17329a5d1c459e3b')