pcr/python-oslo-serialization/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer (Arch): Carl George < arch at cgtx dot us >
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_name="oslo.serialization"
_module="${_name/./-}"

pkgname=("python-${_module}" "python2-${_module}")
pkgver="1.8.0"
pkgrel="1"
pkgdesc="Oslo Serialization library"
arch=("any")
url="https://github.com/openstack/${_name}"
license=("Apache")
makedepends=("git" "python-pbr>=1.3" "python2-pbr>=1.3")
source=("https://pypi.python.org/packages/source/${_name:0:1}/${_name}/${_name}-${pkgver}.tar.gz")
sha256sums=('89156873f2dfa4aed0265ca9c27d7e66c9aff6cfd5b01cafd2eb4e6bd462579b')

package_python-oslo-serialization() {
    depends=("python-babel>=1.3"
             "python-six>=1.9.0"
             "python-msgpack>=0.4.0"
             "python-iso8601>=0.1.9"
             "python-oslo-utils>=1.9.0"
             "python-pbr>=1.3"
             "python-pytz>=2013.6")
    cd "${srcdir}/${_name}-${pkgver}"
    python setup.py install --root="${pkgdir}" --optimize=1
}

package_python2-oslo-serialization() {
    depends=("python2-babel>=1.3"
             "python2-six>=1.9.0"
             "python2-msgpack>=0.4.0"
             "python2-iso8601>=0.1.9"
             "python2-oslo-utils>=1.9.0"
             "python2-pbr>=1.3"
             "python2-pytz>=2013.6")
    cd "${srcdir}/${_name}-${pkgver}"
    python2 setup.py install --root="${pkgdir}" --optimize=1
}