blob: 5f6de3ff8ff5ab33bd4b28ee8e622526ec69f02f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): speps <speps@aur.archlinux.org>
pkgname=dianara
pkgver=1.3.0
pkgrel=1
pkgdesc="A Qt pump.io client"
arch=(i686 x86_64)
url="http://dianara.nongnu.org/"
license=('GPL')
depends=('file' 'qjson' 'qoauth' 'qca-ossl')
install="$pkgname.install"
source=("http://download-mirror.savannah.gnu.org/releases/$pkgname/$pkgname-v$pkgver.tar.gz")
md5sums=('a3f48c9fc1e363bdfabd4f8b1e869315')
prepare() {
cd $pkgname-v$pkgver
[ -d b ] || mkdir b
}
build() {
cd $pkgname-v$pkgver/b
qmake-qt4 ..
make
}
package() {
cd $pkgname-v$pkgver
# bin
install -Dm755 b/$pkgname \
"$pkgdir/usr/bin/$pkgname"
# desktop file
install -Dm644 $pkgname.desktop \
"$pkgdir/usr/share/applications/$pkgname.desktop"
# icons
install -Dm644 icon/32x32/$pkgname.png \
"$pkgdir/usr/share/icons/hicolor/32x32/apps/$pkgname.png"
install -Dm644 icon/64x64/$pkgname.png \
"$pkgdir/usr/share/icons/hicolor/64x64/apps/$pkgname.png"
# translations
install -d "$pkgdir/usr/share/locale"
install -Dm644 translations/*.qm \
"$pkgdir/usr/share/locale"
# man
install -Dm644 manual/$pkgname.1 \
"$pkgdir/usr/share/man/man1/$pkgname.1"
}
# vim:set ts=2 sw=2 et:
|
