1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
|
# $Id$
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Maintainer (Parabola): Nicolas Reynolds <fauno@kiwwwi.com.ar>
# Maintainer (Parabola): Jorge López <jorginho@lavabit.com>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
pkgbase=virtualbox-libre
pkgname=('virtualbox-libre'
'virtualbox-libre-sdk'
'virtualbox-libre-host-source'
'virtualbox-libre-guest-additions'
'virtualbox-libre-guest-source')
pkgver=4.2.0
pkgrel=2
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL' 'custom')
makedepends=('libstdc++5' 'bin86' 'dev86' 'iasl' 'libxslt' 'libxml2' 'libxcursor' 'qt' 'libidl2' 'sdl_ttf' 'alsa-lib' 'libpulse' 'libxtst'
'xalan-c' 'sdl-libre' 'libxmu' 'curl' 'python2' 'linux-libre-headers' 'mesa' 'libxrandr' 'libxinerama' 'libvncserver' 'jdk7-openjdk' 'gsoap' 'vde2' 'cdrkit')
#'xorg-server-devel' 'xf86driproto' 'libxcomposite')
[[ $CARCH == "x86_64" ]] && makedepends=("${makedepends[@]}" 'gcc-multilib' 'lib32-glibc')
source=(http://download.virtualbox.org/virtualbox/${pkgver}/VirtualBox-${pkgver}.tar.bz2
10-vboxdrv.rules vboxdrv-reference.patch LocalConfig.kmk
change_default_driver_dir.patch vboxservice.conf vboxservice.rc vboxservice.service
vboxweb.conf vboxweb.rc vboxweb.service os_blag_64.png os_blag.png os_dragora_64.png
os_dragora.png os_dynebolic.png os_gnewsense_64.png os_gnewsense.png os_gnu_64.png
os_gnuhurd.png os_gnulinux_64.png os_gnulinux.png os_gnu.png os_musix_64.png
os_musix.png os_parabola_64.png os_parabola.png os_trisquel_64.png os_trisquel.png
os_ututo_64.png os_ututo.png os_venenux.png libre.patch free-distros.patch)
md5sums=('691b4134983ce7d89b9fb683305cb647'
'5f85710e0b8606de967716ded7b2d351'
'aa0c090e33aab3e2853b679cc52cba2a'
'58d6e5bb4b4c1c6f3f0b3daa6aaeed03'
'97e193f050574dd272a38e5ee5ebe62b'
'3c08ad30b89add47d3f45121200a5360'
'7d9823507206de9b8528a72af2f18d74'
'07c5f6d86c4b7839d719c8ee0c53653b'
'7e9483b1069a54f181546083ac7e5469'
'c159d683ba1947290fc2ad2c64194150'
'bc9efed88e0469cd7fc460d5a5cd7b4b'
'8538dba8686d7449cb481c9bae9d722a'
'545c925b46f2ac95e5f8ae407fad101a'
'f6416f509c2e5460e4dc624e0a57f3c1'
'bbfb59dd517c020a23701b480187a355'
'efacfdb61918286ea9bc89866b8fd239'
'7c3eb09995e8bafeef414374e44ad4ce'
'a49ed3ab6bd0fb084de0ab3dd97ae93e'
'6b432b3305ed446125eef052c38355a6'
'a70022a468bd3e9daf01818d2d74ac3c'
'6b432b3305ed446125eef052c38355a6'
'a70022a468bd3e9daf01818d2d74ac3c'
'a70022a468bd3e9daf01818d2d74ac3c'
'380eb2ab6cad3da198094585853c129c'
'a60bb9a98abcc3c34156f9051d00df9a'
'3a908ef6952bcf987e63ef2fe4e98d24'
'02e87c39c353634cecacf98f1707fa15'
'0cf41a41e7a415d404d5584e047fd450'
'449cde3b58390284b59c5d663de3edc9'
'c7951fe6888d939f3a7d0dafe477e82b'
'4da8eeb2ece7e475fc7a0d1003da26c6'
'5e4187af59726d71c5be48d0cd816c34'
'67cc4c8611890038eb3e4114ae899525'
'980675863553880453da168b9450d724')
_extramodules=extramodules-3.5-LIBRE
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)" || true
build() {
cd "VirtualBox-$pkgver"
patch -Np1 -i "$srcdir/vboxdrv-reference.patch"
patch -Np1 -i "$srcdir/change_default_driver_dir.patch"
patch -Np1 -i "$srcdir/libre.patch"
patch -Np1 -i "$srcdir/free-distros.patch"
## Removing Nonfree directories
rm -rv "./include/VBox/ExtPack"
rm -rv "./src/VBox/ExtPacks"
rm -rv "./src/VBox/Main/src-helper-apps"
## Removing Oracle VM VirtualBox Extension Pack icons
rm -v "./src/VBox/Resources/darwin/virtualbox-vbox-extpack.icns"
rm -v "./src/VBox/Resources/other/virtualbox-vbox-extpack-"{16px,20px,24px,32px,40px,48px,64px,72px,80px,96px,128px,256px,512px}.png
rm -v "./src/VBox/Resources/win/OSE/virtualbox-vbox-extpack.ico"
rm -v "./src/VBox/Frontends/VirtualBox/images/extension_pack_"{16px,32px,disabled{_16px,_32px},install{_16px,_32px},install_disabled{_16px,_32px},uninstall{_16px,_32px},uninstall_disabled{_16px,_32px}}.png
## Adding free distros icons
for i in {gnuhurd,dynebolic,venenux,{gnu{,linux},parabola,gnewsense,blag,dragora,ututo,musix,trisquel}{,_64}}; do
cp -v "$srcdir/os_${i}.png" "./src/VBox/Frontends/VirtualBox/images"
done
## Removing non-free OS icons
rm -v "./src/VBox/Frontends/VirtualBox/images/os_"{{{arch,turbo}linux,debian,fedora,gentoo,linux{24,26},macosx,mandriva,{free,net,open}bsd,redhat,solaris,opensuse,oracle{,solaris},ubuntu,win{2k{3,8},7,8,vista,xp},xandros}{,_64},dos,jrockitve,l4,linux{,22,_other},netware,qnx,os2{_other,ecs,warp{3,4,45}},win{2k,31,95,98,_other,me,nt4}}.png
cp "$srcdir/LocalConfig.kmk" .
# fake makeself binary to compile without nofatal
ln -s /bin/echo makeself
export PATH="$CWD:$PATH"
./configure --disable-docs \
--enable-webservice \
--enable-vde \
--enable-vnc \
--with-linux=/usr/src/linux-${_kernver}
source ./env.sh
kmk all
sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' "out/linux.$BUILD_PLATFORM_ARCH/release/bin/vboxshell.py"
# build rdesktop-vrdp (broken from LocalConfig.kmk)
cd src/VBox/RDP/client
cp "$srcdir/LocalConfig.kmk" .
kmk all
}
package_virtualbox-libre() {
pkgdesc="Powerful x86 virtualization for enterprise as well as home use (without non-free distros and others OS presets for the VM creation wizard; Oracle VM VirtualBox Extension Pack support removed)"
depends=('virtualbox-libre-host-modules' 'libxml2' 'libxcursor' 'libxinerama' 'sdl-libre' 'libxmu' 'curl' 'libvncserver' 'libpng')
optdepends=('qt: for VirtualBox GUI'
'vde2: Virtual Distributed Ethernet support'
'virtualbox-libre-sdk: developer kit'
'virtualbox-libre-host-source: host kernel libre source modules for non-stock kernels'
'net-tools: for host-only or bridged networking')
backup=('etc/vbox/vbox.cfg' 'etc/conf.d/vboxweb')
replaces=('virtualbox' 'virtualbox-ose')
conflicts=('virtualbox' 'virtualbox-ose')
provides=("virtualbox=$pkgver")
install=virtualbox-libre.install
source "VirtualBox-$pkgver/env.sh"
cd "VirtualBox-$pkgver/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
install -dm755 "$pkgdir"/usr/{bin,lib/virtualbox/components,share/virtualbox/nls,share/virtualbox/rdesktop-vrdp-keymaps}
#Binaries and Wrapper with Launchers
install -m 0755 VBox.sh "$pkgdir/usr/bin/VBox"
for i in VBoxHeadless VBoxManage VBoxSDL VirtualBox vboxwebsrv VBoxBalloonCtrl; do
ln -sf VBox "$pkgdir/usr/bin/$i"
ln -sf VBox "$pkgdir/usr/bin/${i,,}"
done
install -m 0755 VBoxTunctl "$pkgdir/usr/bin"
install -m 0755 rdesktop-vrdp "$pkgdir/usr/bin"
#components
install -m 0755 components/* -t "$pkgdir/usr/lib/virtualbox/components"
#lib
install -m 0755 *.so "$pkgdir/usr/lib/virtualbox"
install -m 0644 *.gc *.r0 VBoxEFI*.fd "$pkgdir/usr/lib/virtualbox"
#setuid root binaries
install -m 4755 VBoxSDL VirtualBox VBoxHeadless VBoxNetDHCP VBoxNetAdpCtl -t "$pkgdir/usr/lib/virtualbox"
#other binaries
install -m 0755 VBoxManage VBoxSVC VBoxXPCOMIPCD VBoxTestOGL VBoxBalloonCtrl vboxwebsrv webtest -t "$pkgdir/usr/lib/virtualbox"
#language
install -m 0755 nls/*.qm -t "$pkgdir/usr/share/virtualbox/nls"
#rdesktop keymaps
install -m 0644 rdesktop-vrdp-keymaps/* "$pkgdir/usr/share/virtualbox/rdesktop-vrdp-keymaps"
#useless scripts
install -m 0755 VBoxCreateUSBNode.sh VBoxSysInfo.sh -t "$pkgdir/usr/share/virtualbox"
#icons
install -D -m 0644 VBox.png "$pkgdir/usr/share/pixmaps/VBox.png"
pushd icons
for i in *; do
install -d "$pkgdir/usr/share/icons/hicolor/$i/mimetypes"
cp $i/* "$pkgdir/usr/share/icons/hicolor/$i/mimetypes"
done
popd
#desktop
install -D -m 0644 virtualbox.desktop "$pkgdir/usr/share/applications/virtualbox.desktop"
install -D -m 0644 virtualbox.xml "$pkgdir/usr/share/mime/packages/virtualbox.xml"
#install configuration
mkdir -p "$pkgdir/etc/vbox"
echo 'INSTALL_DIR=/usr/lib/virtualbox' > "$pkgdir/etc/vbox/vbox.cfg"
#udev and licence
install -D -m 0644 "$srcdir/VirtualBox-${pkgver}/COPYING" \
"$pkgdir/usr/share/licenses/virtualbox/LICENSE"
install -D -m 0644 "$srcdir/10-vboxdrv.rules" \
"$pkgdir/usr/lib/udev/rules.d/10-vboxdrv.rules"
# install rc.d script
install -D -m755 "$srcdir/vboxweb.rc" "$pkgdir/etc/rc.d/vboxweb"
# install systemd service
install -D -m644 "$srcdir/vboxweb.service" \
"$pkgdir/usr/lib/systemd/system/vboxweb.service"
# install sample config
install -D -m644 "$srcdir/vboxweb.conf" "$pkgdir/etc/conf.d/vboxweb"
}
package_virtualbox-libre-sdk() {
pkgdesc='VirtualBox Software Developer Kit (SDK)'
depends=('python2')
replaces=('virtualbox-sdk')
conflicts=('virtualbox-sdk')
provides=("virtualbox-sdk=$pkgver")
install -dm755 "$pkgdir/usr/lib/virtualbox"
source "VirtualBox-$pkgver/env.sh"
cd "VirtualBox-$pkgver/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
install -D -m 0755 vboxshell.py "$pkgdir/usr/lib/virtualbox/vboxshell.py"
#python sdk
pushd sdk/installer
VBOX_INSTALL_PATH="/usr/lib/virtualbox" python2 vboxapisetup.py install --root "${pkgdir}"
popd
rm -rf sdk/installer
mv sdk "$pkgdir/usr/lib/virtualbox"
}
package_virtualbox-libre-host-source() {
pkgdesc='VirtualBox kernel libre modules source'
depends=('dkms' 'gcc' 'make')
provides=("virtualbox-host-source=$pkgver" 'virtualbox-libre-host-modules')
replaces=('virtualbox-host-source' 'virtualbox-source' 'virtualbox-libre-source')
conflicts=('virtualbox-host-source' 'virtualbox-source' 'virtualbox-libre-source')
optdepends=('linux-libre-headers'
'linux-libre-lts-headers')
install=virtualbox-libre-host-source.install
install -dm755 "$pkgdir/usr/src"
source "VirtualBox-$pkgver/env.sh"
cd "VirtualBox-$pkgver/out/linux.$BUILD_PLATFORM_ARCH/release/bin"
cp -r src "$pkgdir/usr/src/vboxhost-$pkgver"
}
package_virtualbox-libre-guest-source() {
pkgdesc='VirtualBox Additions kernel libre modules source'
depends=('dkms' 'gcc' 'make')
provides=("virtualbox-guest-source=${pkgver}" 'virtualbox-libre-guest-modules')
replaces=('virtualbox-guest-source' 'virtualbox-archlinux-source' 'virtualbox-parabola-source')
conflicts=('virtualbox-guest-source' 'virtualbox-archlinux-source' 'virtualbox-parabola-source')
optdepends=('linux-libre-headers'
'linux-libre-lts-headers')
install=virtualbox-libre-guest-source.install
install -dm755 "$pkgdir/usr/src"
source "VirtualBox-$pkgver/env.sh"
cd "VirtualBox-$pkgver/out/linux.$BUILD_PLATFORM_ARCH/release/bin/additions"
cp -r src "$pkgdir/usr/src/vboxguest-$pkgver"
}
package_virtualbox-libre-guest-additions(){
pkgdesc='Additions for guests only (userspace tools)'
depends=('virtualbox-libre-guest-modules' 'gcc-libs' 'libxmu' 'xorg-xrandr' 'libxfixes')
provides=("virtualbox-guest-additions=${pkgver}")
replaces=('virtualbox-guest-additions' 'virtualbox-archlinux-additions' 'virtualbox-parabola-additions')
conflicts=('virtualbox-guest-additions' 'virtualbox-archlinux-additions' 'virtualbox-parabola-additions')
backup=('etc/conf.d/vboxservice')
install=virtualbox-libre-guest-additions.install
source "VirtualBox-$pkgver/env.sh"
cd "VirtualBox-$pkgver/out/linux.$BUILD_PLATFORM_ARCH/release/bin/additions"
install -d "$pkgdir"/{usr/bin,sbin}
install -m755 VBoxClient VBoxControl VBoxService "$pkgdir/usr/bin"
install -m755 mount.vboxsf "$pkgdir/sbin"
install -m755 -D "$srcdir"/VirtualBox-$pkgver/src/VBox/Additions/x11/Installer/98vboxadd-xclient \
"$pkgdir"/usr/bin/VBoxClient-all
install -m755 -D "$srcdir"/VirtualBox-$pkgver/src/VBox/Additions/x11/Installer/vboxclient.desktop \
"$pkgdir"/etc/xdg/autostart/vboxclient.desktop
install -D vboxvideo_drv_112.so \
"$pkgdir/usr/lib/xorg/modules/drivers/vboxvideo.so"
install -d "$pkgdir/usr/lib/xorg/modules/dri"
install -m755 VBoxOGL*.so "$pkgdir/usr/lib"
ln -s /usr/lib/VBoxOGL.so "$pkgdir/usr/lib/xorg/modules/dri/vboxvideo_dri.so"
install -m755 -D pam_vbox.so "$pkgdir/usr/lib/security/pam_vbox.so"
# install rc.d script
install -D -m755 "$srcdir/vboxservice.rc" "$pkgdir/etc/rc.d/vboxservice"
# install sample config
install -D -m644 "$srcdir/vboxservice.conf" "$pkgdir/etc/conf.d/vboxservice"
# install systemd service file
install -D -m644 "$srcdir/vboxservice.service" \
"$pkgdir/usr/lib/systemd/system/vboxservice.service"
}
|
