blob: 6a395a0ddddccfa49171ed40009cb9c46b1f07b2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer (Arch): Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor (Arch): xduugu
# Contributor (Arch): nh2
# Contributor (Arch): Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor (Arch): Nick B <Shirakawasuna ð gmail đ com>
# Contributor (Arch): Christof Musik <christof ð senfdax đ de>
# Contributor (Arch): Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor (Arch): Ignas Anikevicius <anikevicius ð gmail đ com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Márcio Silva <coadde@parabola.nu>
_basekernel=3.16
_kernelname= # libre/linux-libre{,-lts}
_pkgname=tp_smapi
pkgname=${_pkgname}${_kernelname}-parabola
pkgver=0.41
pkgrel=52.2 # linux-libre=52.2 | linux-libre-lts=29.1
_extramodules=extramodules-${_basekernel}${_kernelname}
pkgdesc="Modules for ThinkPad's SMAPI functionality (built for the linux-libre${_kernelname} kernel package)"
arch=('i686' 'x86_64' 'mips64el')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
depends=("linux-libre${_kernelname}>=${_basekernel}" "linux-libre${_kernelname}<${_toohigh}")
makedepends=("linux-libre${_kernelname}-headers>=${_basekernel}" "linux-libre${_kernelname}-headers<${_toohigh}")
replaces=("${_pkgname}${_kernelname}" "${_pkgname}-libre${_kernelname}")
conflicts=("${_pkgname}${_kernelname}" "${_pkgname}-libre${_kernelname}")
provides=("${_pkgname}${_kernelname}=${pkgver}")
install='kmod.install'
source=("https://github.com/downloads/evgeni/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
md5sums=('63c683415c764568f6bf17c7eabe4752')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
sed -ri -e "s/^(KVER\s*:=).*$/\1 ${_kernver}/" \
-e "s#^(KBASE\s*:=).*\$#\1 /usr/lib/modules/${_kernver}#" Makefile
make HDAPS=1
}
package() {
_kernver="$(cat /usr/lib/modules/${_extramodules}/version)"
# Actually install
make -C "/usr/lib/modules/${_kernver}/build" \
INSTALL_MOD_PATH="${pkgdir}/usr" \
M="${srcdir}/${_pkgname}-${pkgver}" modules_install
cd "${pkgdir}/usr/lib/modules"
mv "${_kernver}/extra" "${_extramodules}"
rmdir "${_kernver}"
# compress kernel modules
find "${pkgdir}" -name "*.ko" -exec gzip -9 {} +
# load module on startup
install -dm 755 "${pkgdir}/usr/lib/modules-load.d"
echo ${_pkgname} > "${pkgdir}/usr/lib/modules-load.d/${_pkgname}${_kernelname}.conf"
# Set the correct extramodules directory for install
cp -f "${startdir}/${install}" "${startdir}/${install}.pkg"
true && install=${install}.pkg
sed -i "s/^_EXTRAMODULES=.*/_EXTRAMODULES="${_extramodules}"/" "${startdir}/${install}"
}
|
