blob: d30a61137213b8c661c2a2ec73cd013101b56bd6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# $Id$
# Maintainer: Sébastien Luttringer <seblu@aur.archlinux.org>
# Maintainer (Parabola): André Silva <andre.paulista@adinet.com.uy>
pkgbase=linux-libre-tools
pkgname=('perf-libre' 'cpupower-libre')
pkgver=3.3
kernver=${pkgver}
pkgrel=2
license=('GPL2')
arch=('i686' 'x86_64' 'mips64el')
url='http://linux-libre.fsfla.org/'
options=('!strip')
makedepends=('asciidoc' 'xmlto')
# split packages need all package dependencies set manually in makedepends
makedepends+=('python2-libre' 'libnewt' 'elfutils' 'pciutils')
source=("http://linux-libre.fsfla.org/pub/linux-libre/releases/$kernver-gnu/linux-libre-$kernver-gnu.tar.xz"
'cpupower.rc'
'cpupower.conf'
'cpupower.service')
md5sums=('5487da14ca81715a469c7594d39722fa'
'26af384ca282bc0dc38ff65acc7bb4b9'
'18d5aa9e4c6bb23bb02bf65e155e0f0e'
'20870541e88109d2f153be3c58a277f1')
build() {
msg2 'Build perf'
cd linux-$kernver/tools/perf
make PYTHON=python2 DESTDIR="${pkgdir}/usr" perfexecdir="lib/$pkgname" \
PERF_VERSION=$pkgver-$pkgrel all man
msg2 'Build cpupower'
# we cannot use --as-needed
LDFLAGS=${LDFLAGS:+"$LDFLAGS,--no-as-needed"}
cd "$srcdir/linux-$kernver/tools/power/cpupower"
make VERSION=$pkgver-$pkgrel
}
package_perf-libre() {
pkgdesc='Linux-libre kernel performance auditing tool'
depends=('python2-libre' 'libnewt' 'elfutils')
replaces=('perf')
conflicts=('perf')
provides=("perf=$pkgver")
cd linux-${kernver}/tools/perf
make PYTHON=python2 DESTDIR="${pkgdir}/usr" perfexecdir="lib/$pkgname" \
PERF_VERSION=$pkgver install install-man
}
package_cpupower-libre() {
pkgdesc='Linux-libre kernel tool to examine and tune power saving related features of your processor'
backup=('etc/conf.d/cpupower')
depends=('pciutils')
replaces=('cpupower')
conflicts=('cpupower' 'cpufrequtils')
provides=("cpupower=$pkgver")
cd linux-$kernver/tools/power/cpupower
make \
DESTDIR="$pkgdir" \
mandir='/usr/share/man' \
docdir='/usr/share/doc/cpupower' \
install install-man
# install rc.d script
cd "$srcdir"
install -D -m 755 cpupower.rc "$pkgdir/etc/rc.d/cpupower"
install -D -m 644 cpupower.conf "$pkgdir/etc/conf.d/cpupower"
install -D -m 644 cpupower.service "$pkgdir/usr/lib/systemd/system/cpupower.service"
}
# vim:set ts=2 sw=2 ft=sh et:
|
