blob: 97a0fd198b2e888476293628d9c1100595955a61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 124730 2011-05-24 07:10:29Z ibiru $
# Maintainer: Jan de Groot <jgc@archlinux.org>
_pkgname=file-roller
pkgname=file-roller-libre
pkgver=3.0.2
pkgrel=1
pkgdesc="Archive manipulator for GNOME"
arch=('i686' 'x86_64')
license=('GPL')
depends=('desktop-file-utils' 'gtk3' 'hicolor-icon-theme' 'dconf' 'nautilus')
makedepends=('intltool' 'gnome-doc-utils' 'pkg-config' 'nautilus' 'libsm')
optdepends=('ununrar: interface to unarchiver, the free RAR uncompression program'
'zip: creates PKZIP-compatible .zip files'
'unzip: unpacks .zip archives'
'p7zip: 7zip compression utility'
'xz: managing LZMA and XZ compressed files'
'arj: ARJ archiver')
groups=('gnome-extra')
provides=("$_pkgname=$pkgver")
replaces=("$_pkgname")
conflicts=("$_pkgname")
options=('!libtool' '!emptydirs')
install=file-roller.install
url="http://www.gnome.org"
source=(http://ftp.gnome.org/pub/gnome/sources/${_pkgname}/${pkgver%.*}/${_pkgname}-${pkgver}.tar.bz2)
sha256sums=('a612f05c44f82328175ddca1b4a1da214d9c305797370b78435f490b250af3d1')
build() {
cd "${srcdir}/${_pkgname}-${pkgver}"
./configure --prefix=/usr --sysconfdir=/etc \
--libexecdir=/usr/lib/file-roller \
--localstatedir=/var --disable-static \
--disable-scrollkeeper --disable-schemas-compile
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
}
|
