1 files changed, 61 insertions, 0 deletions
diff --git a/pcr/spl-dkms/PKGBUILD b/pcr/spl-dkms/PKGBUILD
new file mode 100644
index 000000000..b93bde6df
--- /dev/null
+++ b/pcr/spl-dkms/PKGBUILD
@@ -0,0 +1,61 @@
+#
+# Maintainer (Arch): Iacopo Isimbaldi <isiachi@rhye.it>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+#
+
+pkgbase="spl-dkms"
+pkgname=("spl-dkms" "spl-utils")
+pkgver=0.6.5.6
+pkgrel=2
+license=('GPL')
+makedepends=("git")
+arch=("i686" "x86_64")
+url="http://zfsonlinux.org/"
+source=("git+https://github.com/zfsonlinux/spl.git#tag=spl-${pkgver}"
+        "spl-utils.hostid")
+sha256sums=('SKIP'
+            'ad95131bc0b799c0b1af477fb14fcf26a6a9f76079e48bf090acb7e8367bfd0e')
+
+build() {
+    cd "${srcdir}/spl"
+    ./autogen.sh
+
+    _at_enable=""
+    [ "${CARCH}" == "i686"  ] && _at_enable="--enable-atomic-spinlocks"
+
+    ./configure --prefix=/usr \
+                --libdir=/usr/lib \
+                --sbindir=/usr/bin \
+                --with-config=user \
+                ${_at_enable}
+
+    make
+}
+
+package_spl-dkms() {
+    pkgdesc="Solaris Porting Layer kernel modules."
+    depends=("dkms" "spl-utils=${pkgver}-${pkgrel}")
+    provides=("spl")
+    conflicts=("spl-git" "spl-lts")
+    install=spl.install
+
+    dkmsdir="${pkgdir}/usr/src/spl-${pkgver}"
+    install -d "${dkmsdir}"
+    cp -a ${srcdir}/spl/. ${dkmsdir}
+
+    cd "${dkmsdir}"
+    make clean distclean
+    find . -name ".git*" -print0 | xargs -0 rm -fr --
+    scripts/dkms.mkconf -v ${pkgver} -f dkms.conf -n spl
+    chmod g-w,o-w -R .
+}
+
+package_spl-utils() {
+    pkgdesc="Solaris Porting Layer kernel module support files."
+    conflicts=("spl-utils-git" "spl-utils-lts")
+
+    cd "${srcdir}/spl"
+    make DESTDIR="${pkgdir}" install
+
+    install -D -m644 "${srcdir}"/spl-utils.hostid "${pkgdir}"/etc/hostid
+}