1 files changed, 48 insertions, 0 deletions
diff --git a/nonprism/centerim-nonprism/PKGBUILD b/nonprism/centerim-nonprism/PKGBUILD
new file mode 100644
index 000000000..1863e006b
--- /dev/null
+++ b/nonprism/centerim-nonprism/PKGBUILD
@@ -0,0 +1,48 @@
+# $Id: PKGBUILD 78820 2012-10-25 06:47:28Z foutrelis $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Aaron Griffin <aaron@archlinux.org>
+# Contributor: shild <sxp@bk.ru>
+
+_pkgname=centerim
+pkgname=centerim-nonprism
+pkgver=4.22.10
+pkgrel=2
+pkgdesc="Fork of CenterICQ - A text mode menu- and window-driven IM interface, without support for unsafe and dangerous for privacy protocols"
+arch=('i686' 'x86_64')
+url="http://www.centerim.org"
+license=('GPL')
+depends=('python2' 'libjpeg' 'gpgme')
+replaces=("$_pkgname" 'centericq')
+conflicts=$_pkgname
+provides=$_pkgname=$pkgver
+source=("http://www.centerim.org/download/releases/$_pkgname-$pkgver.tar.gz"
+        'nonprism.patch')
+md5sums=('7565c3c8cac98a4e2d8524076a44676f'
+         '74887744683b68ea37d4d020c80fb675')
+
+prepare() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  # add patch to remove more protocols
+  patch -Np1 -i "${srcdir}/nonprism.patch"
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  sed -i 's#python#python2#' misc/CenterIMLog2HTML.py
+  sed -i '1,1i#include <stdio.h>' libicq2000/libicq2000/sigslot.h
+  ./configure --prefix=/usr \
+              --with-ssl \
+              --with-openssl \
+              --enable-locales-fix \
+              --disable-icq \
+              --disable-yahoo \
+              --disable-aim \
+              --disable-gg \
+              --disable-msn
+  make
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install
+}