1 files changed, 41 insertions, 0 deletions
diff --git a/libre/java-commons-net1/PKGBUILD b/libre/java-commons-net1/PKGBUILD
new file mode 100644
index 000000000..a115fb815
--- /dev/null
+++ b/libre/java-commons-net1/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer (Arch): Guillaume ALAUX <guillaume@archlinux.org>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+
+_libname=commons-net
+pkgname=java-${_libname}1
+pkgver=1.4.1
+pkgrel=2.parabola1
+pkgdesc="Apache library that implements the client side of many basic Internet protocols"
+arch=('any')
+url="http://commons.apache.org/net/"
+license=('APACHE')
+depends=('java-runtime-headless')
+makedepends=('apache-ant' 'jakarta-oro' 'jh')
+source=("https://archive.apache.org/dist/commons/net/source/${_libname}-${pkgver}-src.tar.gz")
+md5sums=('ccbb3f67b55e8a7a676499db4386673c')
+
+build() {
+  cd "${srcdir}/${_libname}-${pkgver}"
+  ant dist -Dnoget=true -lib "/usr/share/java/jakarta-oro.jar"
+}
+
+package() {
+  cd "${srcdir}/${_libname}-${pkgver}"
+
+  # Install license file
+  install -Dm644 LICENSE.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+
+  # Install documentation
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "dist/docs/api" "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -r "src/java/examples" "${pkgdir}/usr/share/doc/${pkgname}/examples"
+
+  # Install Maven artifacts
+  export DESTDIR=${pkgdir}
+  jh mvn-install ${_libname} ${_libname} ${pkgver} \
+    "${srcdir}/${_libname}-${pkgver}/project.xml" \
+    "${srcdir}/${_libname}-${pkgver}/target/${_libname}-${pkgver}.jar" \
+    "${_libname}.jar"
+  ln -s "/usr/share/java/${_libname}.jar" \
+    "${pkgdir}/usr/share/java/${_libname}-${pkgver}.jar"
+}