1 files changed, 40 insertions, 0 deletions
diff --git a/coherence/evolution-data-server-coherence/PKGBUILD b/coherence/evolution-data-server-coherence/PKGBUILD
new file mode 100644
index 000000000..2ba93b16c
--- /dev/null
+++ b/coherence/evolution-data-server-coherence/PKGBUILD
@@ -0,0 +1,40 @@
+
+_pkgname=evolution-data-server
+pkgname=evolution-data-server-coherence
+pkgver=3.8.5
+pkgrel=1
+pkgdesc="Centralized access to appointments and contacts without libgdata support"
+arch=(i686 x86_64)
+depends=(nss krb5 libical db libxml2 libsoup gtk3 libsecret gcr)
+makedepends=(intltool gperf gobject-introspection vala python2 gnome-common)
+options=('!libtool')
+install=$_pkgname.install
+url="http://www.gnome.org"
+license=(GPL)
+replaces=$_pkgname
+conflicts=$_pkgname
+provides=$_pkgname=$pkgver
+source=(http://ftp.gnome.org/pub/gnome/sources/$_pkgname/${pkgver%.*}/$_pkgname-$pkgver.tar.xz)
+sha256sums=('73c4ecfed65651cc72966b90081d7b72f9b42573585bc89797efea65ccfdbd2a')
+
+
+build() {
+  cd "$_pkgname-$pkgver"
+  autoreconf -fi
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --with-openldap=yes \
+      --libexecdir=/usr/lib/evolution-data-server \
+      --with-krb5=/usr --with-libdb=/usr \
+      --without-libgdata \
+      --disable-goa \
+      --disable-google \
+      --disable-weather \
+      --enable-vala-bindings --disable-uoa PYTHON=python2
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
+  make
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+}