zfs-utils-git: add new package to [pcr]

1 files changed, 64 insertions, 0 deletions

diff --git a/pcr/zfs-utils-git/PKGBUILD b/pcr/zfs-utils-git/PKGBUILD
new file mode 100644
index 000000000..dc032e2c5
--- /dev/null
+++ b/pcr/zfs-utils-git/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer (Arch): Jesus Alvarez <jeezusjr at gmail dot com>
+# Contributor (Arch): Kyle Fuller <inbox at kylefuller dot co dot uk>
+# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
+#
+# This PKGBUILD was generated by the archzfs build scripts located at
+#
+# http://github.com/demizer/archzfs
+#
+# The build script generates and updates the pkgver and _kernel* variables.
+#
+pkgname="zfs-utils-git"
+pkgver=0.6.4.2_r0_g44b5ec8_4.1.6_1
+pkgrel=1
+license=('CDDL')
+pkgdesc="Kernel module support files for the Zettabyte File System."
+depends=("spl-git")
+makedepends=("git")
+arch=("i686" "x86_64")
+url="http://zfsonlinux.org/"
+source=("git+https://github.com/zfsonlinux/zfs.git#commit=44b5ec8f"
+        "zfs-utils.bash-completion-r1"
+        "zfs-utils.initcpio.install"
+        "zfs-utils.initcpio.hook")
+groups=("archzfs-git")
+md5sums=('SKIP'
+         '9ddb0c8a94861f929d0fa741fdc49950'
+         '9ef4841abb85dee611828cc7e6f5c6fe'
+         '62ba32c6853c315ff231c396cf8bfdbb')
+replaces=("zfs-utils")
+provides=("zfs-utils")
+conflicts=("zfs-utils" "zfs-utils-lts")
+
+build() {
+    cd "${srcdir}/zfs"
+    ./autogen.sh
+
+    ./configure --prefix=/usr \
+                --sysconfdir=/etc \
+                --sbindir=/usr/bin \
+                --libdir=/usr/lib \
+                --datadir=/usr/share \
+                --includedir=/usr/include \
+                --with-udevdir=/lib/udev \
+                --libexecdir=/usr/lib/zfs \
+                --with-config=user
+    make
+}
+
+package() {
+    cd "${srcdir}/zfs"
+    make DESTDIR="${pkgdir}" install
+
+    # Remove uneeded files
+    rm -r "${pkgdir}"/etc/init.d
+    rm -r "${pkgdir}"/usr/lib/dracut
+
+    # move module tree /lib -> /usr/lib
+    cp -r "${pkgdir}"/{lib,usr}
+    rm -r "${pkgdir}"/lib
+
+    install -D -m644 "${srcdir}"/zfs-utils.initcpio.hook "${pkgdir}"/usr/lib/initcpio/hooks/zfs
+    install -D -m644 "${srcdir}"/zfs-utils.initcpio.install "${pkgdir}"/usr/lib/initcpio/install/zfs
+    install -D -m644 "${srcdir}"/zfs-utils.bash-completion-r1 "${pkgdir}"/usr/share/bash-completion/completions/zfs
+}