kdebase-runtime-libre: add new package to [libre] repo

1 files changed, 57 insertions, 0 deletions

diff --git a/libre/kdebase-runtime-libre/PKGBUILD b/libre/kdebase-runtime-libre/PKGBUILD
new file mode 100644
index 000000000..ea7ec4e00
--- /dev/null
+++ b/libre/kdebase-runtime-libre/PKGBUILD
@@ -0,0 +1,57 @@
+# $Id$
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>
+
+_pkgname=kdebase-runtime
+pkgname=kdebase-runtime-libre
+pkgver=4.9.0
+pkgrel=3
+pkgdesc="Plugins and applications necessary for the running of KDE applications (without non-privacy search providers)"
+arch=('i686' 'x86_64')
+url='https://projects.kde.org/projects/kde/kde-runtime'
+license=('GPL' 'LGPL')
+depends=('nepomuk-core' 'smbclient' 'libssh' 'libcanberra' 'oxygen-icons' 'xorg-xauth'
+         'kactivities')
+makedepends=('pkg-config' 'cmake' 'automoc4' 'kdepimlibs' 'openslp' 'doxygen'
+             'networkmanager')
+optdepends=('kdepimlibs: to generate drkonqi reports'
+            'htdig: to build the search index in khelpcenter'
+            'rarian: needed by khelpcenter'
+            'gdb: drkonq crash handler')
+replaces=("${_pkgname}")
+conflicts=("${_pkgname}")
+provides=("${_pkgname}=${pkgver}")
+install="${_pkgname}.install"
+source=("http://download.kde.org/stable/${pkgver}/src/kde-runtime-${pkgver}.tar.xz"
+        'duckduckgo_lite.desktop')
+sha1sums=('89a9e5c7e52cb925217b45a568a354cc041bc28d'
+          '265d4ca95c3a022b5f6f1d5daea6f8e3a25dee85')
+
+build() {
+    cd "${srcdir}"
+
+# Removing non-privacy search providers 
+    rm -v kde-runtime-${pkgver}/kurifilter-plugins/ikws/searchproviders/{7digital,acronym,altavista,amazon{,_mp3},amg,austronaut,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,froogle,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,gracenote,imdb,jeeves,katatudo,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,vivisimo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop
+
+# Adding DuckDuckGo Lite
+    cp -v duckduckgo_lite.desktop "kde-runtime-${pkgver}/kurifilter-plugins/ikws/searchproviders"
+
+	mkdir build
+	cd build
+	cmake ../kde-runtime-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+        -DWITH_QNtrack=OFF \
+        -DWITH_Xine=OFF
+	make
+}
+
+package() {
+	cd "$srcdir/build"
+	make DESTDIR="$pkgdir" install
+	rm -f "${pkgdir}/usr/share/icons/hicolor/index.theme"
+
+    ln -sf /usr/lib/kde4/libexec/kdesu "${pkgdir}/usr/bin/"
+}