tox-git: add new package to [pcr]

1 files changed, 44 insertions, 0 deletions

diff --git a/pcr/tox-git/PKGBUILD b/pcr/tox-git/PKGBUILD
new file mode 100644
index 000000000..469c457a0
--- /dev/null
+++ b/pcr/tox-git/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer (Arch): Boohbah <boohbah at gmail.com>
+# Contributor (Arch): naxuroqa <naxuroqa at gmail.com>
+
+pkgname=tox-git
+pkgver=r3071.g979b4bf
+pkgrel=1
+pkgdesc="A FOSS instant messaging application aimed to replace Skype (git version)"
+arch=('i686' 'x86_64')
+url="https://tox.im/"
+license=('GPL3')
+depends=('libconfig' 'libsodium' 'libvpx' 'opus')
+makedepends=('check' 'git')
+conflicts=('tox')
+provides=('tox')
+source=("${pkgname}::git+https://github.com/irungentoo/toxcore")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname}"
+  printf "r%s.g%s" \
+    "$(git rev-list --count HEAD)" \
+    "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${pkgname}"
+  autoreconf -i
+  ./configure \
+    --prefix="/usr" \
+    --enable-daemon \
+    --disable-ntox \
+    --disable-tests
+  make
+}
+
+check() {
+  cd "${pkgname}"
+  make check
+}
+
+package() {
+  cd "${pkgname}"
+  make DESTDIR="${pkgdir}" install
+}