# $Id$
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Contributor: Alexander Baldeck <alexander@archlinux.org>
# Arch libdrm Maintainers:
#	Jan de Groot
#	Andreas Radke
# Maintainer (Parabola): Márcio Silva <coadde@adinet.com.uy>

pkgname=libdrm-git
pkgver=20120612
pkgrel=1
pkgdesc="Userspace interface to kernel DRM services"
arch=('i686' 'x86_64' 'mips64el')
license=('custom')
depends=('glibc' 'libpciaccess')
makedepends=('cairo' 'valgrind' 'git')
options=('!libtool')
url="http://dri.freedesktop.org/"
source=(no-pthread-stubs.patch
        COPYING)
sha1sums=('2a5410baa3e6e078f9378ce486a88f41d22fd838'
          'ba3dcd636997ee0d30df14b03dae05c24ae5d094')
provides=('libdrm=2.4.35')
conflicts=('libdrm')

_gitroot='git://git.freedesktop.org/git/mesa/drm'
_gitname='drm'

build() {

  cd "${srcdir}"
  msg "Connecting to GIT server...."

  if [[ -d "${_gitname}" ]]; then
    cd "${_gitname}" && git pull origin
    msg "The local files are updated."
  else
    git clone "${_gitroot}" "${_gitname}"
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting build..."

  rm -rf "${srcdir}/${_gitname}-build"
  git clone "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
  cd "${srcdir}/${_gitname}-build"
  patch -Np1 -i "${srcdir}/no-pthread-stubs.patch"

  #libtoolize --force
  autoreconf --force --install
  ./autogen.sh
  ./configure --prefix=/usr \
      --enable-udev \
      --enable-intel \
      --enable-radeon \
      --enable-vmwgfx-experimental-api \
      --enable-nouveau
  make
}

check() {
  cd "${srcdir}/${_gitname}-build"
  make -k check
}

package() {
  cd "${srcdir}/${_gitname}-build"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 "${srcdir}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/"
}