# Maintainer: Jorge Araya Navarro <elcorreo@deshackra.com>
# Maintainer (aur): Bjoern Bidar <theodorstormgrade@gmail.com>

pkgname='ryzom-hg'
hgver=e7f0b9c
pkgver=20140328
pkgrel=1
pkgdesc="An awesome free software 3D MMORPG game"
arch=('i686' 'x86_64')
url="http://www.ryzom.com/"
license=('AGPL3')
#depends=('nel-hg' 'ryzom-data' 'lua51') # use these when https://bitbucket.org/ryzom/ryzomcore/issue/149 is solved
depends=('libpng' 'libjpeg' 'libwww-hg' 'boost' 'freetype2' 'luabind' 'libogg' 'libvorbis'
  'openal' 'mesa' 'glu' 'lua51' 'ryzom-data')
#conflicts=('ryzom' 'ryzom-client') # see above
conflicts=('ryzom' 'ryzom-client' 'nel-hg' 'ryzom-nel')
makedepends=('mercurial' 'cpptest' 'cmake' 'bison' 'boost' 'rrdtool')
source=("https://repo.parabolagnulinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('fce7d94f1c55afd939ab4943af6480b0d20d4f74f5d357029777f84ac661f869')

mksource=("$pkgname-$pkgver::hg+https://bitbucket.org/ryzom/ryzomcore#revision=${hgver}")
mkdepends=('mercurial')

mksource() {
  cd "$srcdir/$pkgname-$pkgver/"
  rm -rf .hg*
  cd "$srcdir/$pkgname-$pkgver/code/"
  mv * ../
  rm -rf "$srcdir/$pkgname-$pkgver/code/"
  #sed -i 's|<freetype/|<freetype2/|g' "${srcdir}/${srcpkgname}-${pkgver}/nel/src/3d/font_generator.cpp"
}

build() {
  mkdir -p "$srcdir/build-client"
  cd "$srcdir/build-client"
  # WITH_NEL is ON, see above
  cmake -Wno-dev "$srcdir/${pkgname}-${pkgver}" -DFINAL_VERSION=ON -DWITH_STATIC=OFF -DWITH_NEL_TOOLS=OFF -DWITH_NEL_TESTS=OFF -DWITH_LUA51=ON  -DWITH_NEL_SAMPLES=OFF -DWITH_RYZOM_TOOLS=OFF -DWITH_RYZOM_SERVER=OFF -DWITH_RYZOM_CLIENT=ON -DWITH_NEL=ON -DWITH_DRIVER_OPENGL=ON -DWITH_DRIVER_OPENAL=ON -DCMAKE_INSTALL_PREFIX=/usr -DRYZOM_ETC_PREFIX=/etc/ryzom -DRYZOM_SHARE_PREFIX=/usr/share/ryzom -DRYZOM_BIN_PREFIX=/usr/bin -DRYZOM_GAMES_PREFIX=/usr/bin -DFREETYPE_INCLUDE_DIRS="/usr/include;/usr/include/freetype2"

 # cmake -Wno-dev "$srcdir/${pkgname}-${pkgver}" -DFINAL_VERSION=ON -DWITH_STATIC=OFF -DWITH_NEL_TOOLS=OFF -DWITH_NEL_TESTS=OFF -DWITH_LUA51=ON  -DWITH_NEL_SAMPLES=OFF -DWITH_RYZOM_TOOLS=OFF -DWITH_RYZOM_SERVER=OFF -DWITH_RYZOM_CLIENT=ON -DWITH_NEL=OFF -DWITH_DRIVER_OPENGL=ON -DWITH_DRIVER_OPENAL=ON -DCMAKE_INSTALL_PREFIX=/usr -DRYZOM_ETC_PREFIX=/etc/ryzom -DRYZOM_SHARE_PREFIX=/usr/share/ryzom -DRYZOM_BIN_PREFIX=/usr/bin -DRYZOM_GAMES_PREFIX=/usr/bin -DLUA_INCLUDE_DIR="/usr/include/lua5.1/" -DLIBWWW_INCLUDE_DIR="/usr/include/w3c-libwww/"
  
  make -j1 all
}

package() {
  cd "$srcdir/build-client"
  make DESTDIR="$pkgdir" install
  cd "$pkgdir/etc/ryzom/"
  # instead of the open shard, we point to the actual ryzom shard.
  # this cannot be on prepare(), I tried that already and didn't work
  sed -i 's|"ryzom_open"|"ryzom_live"|g' client_default.cfg
  sed -i 's|PatchServer = "";|PatchServer = "http://dl.ryzom.com/patch_live";|g' client_default.cfg
  sed -i 's|SignUpURL = "";|SignUpURL = "http://www.ryzom.com/subscribe";|g' client_default.cfg
  sed -i 's|"open.ryzom.com:40916";|"shard.ryzom.com:40916";|g' client_default.cfg
  sed -i 's|CreateAccountURL = "";|CreateAccountURL = "https://secure.ryzom.com/signup/from_client.php";|g' client_default.cfg
  sed -i 's|InstallWebPage = "";|InstallWebPage = "http://dl.ryzom.com/installer/";|g' client_default.cfg
  sed -i 's|"http://open.ryzom.com:50000/stats/stats.php";|"http://shard.ryzom.com:50000/stats/stats.php";|g' client_default.cfg
  sed -i 's|atys.|app.|g' client_default.cfg
  sed -i 's|"app.ryzom.com" |"api.ryzom.com", "app.ryzom.com" |g' client_default.cfg
}