# $Id: pkgbuild-mode.el,v 1.23 2007/10/20 16:02:14 juergen Exp $
# Maintainer: Jorge Araya Navarro <jorgean@lavabit.com>
pkgname=ryzom-hg-nel
pkgver=20130706
pkgrel=5
pkgdesc="An awesome free software 3D MMORPG game, Game client."
arch=('i686' 'x86_64')
url="http://www.ryzom.com/"
license=('AGPL')
groups=("ryzom-hg")
depends=('curl' 'freetype2' 'libx11' 'mesa' 'libxxf86vm' 'openal' 'freealut' 'libogg' 'libvorbis' 'libxml2' 'libpng' 'libjpeg' 'rrdtool' 'libwww' 'boost'  'luabind' 'libsquish' 'lua51' 'lua51-sql-mysql')
makedepends=('cpptest' 'cmake' 'bison')
provides=("ryzom-hg-nel")
conflicts=("ryzom-hg-nel")
replaces=("ryzom-hg-nel")

source=("http://repo.parabolagnulinux.org/other/ryzom-$pkgver-2-any.src.tar.gz")
sha256sums=('03ddd23d0b2e92c419dcdebe264890b5b1c906992ae93225be43869739f9f475')

mksource=("$pkgname-$pkgver-${pkgrel}::hg+https://bitbucket.org/ryzomcore")

_CMAKE_COMMON_ARGS=('-DWITH_STATIC=OFF' '-DWITH_NEL_TOOLS=OFF' '-DWITH_NEL_TESTS=OFF' '-DWITH_NEL_SAMPLES=OFF' '-DWITH_RYZOM_TOOLS=OFF') # cmake arguments for server and client

_CMAKE_LIB_ARGS=('-DWITH_RYZOM_SERVER=OFF' '-DWITH_RYZOM_CLIENT=OFF' '-DWITH_NEL=ON')

build() {
  mkdir -p "$srcdir/build-nel"
  cd "$srcdir/build-nel"
  cmake -b -Wno-dev "$srcdir/code" ${_CMAKE_COMMON_ARGS[*]} ${_CMAKE_LIB_ARGS[*]} -DCMAKE_INSTALL_PREFIX=/usr -DRYZOM_ETC_PREFIX=/etc/ryzom -DRYZOM_SHARE_PREFIX=/usr/share/ryzom -DRYZOM_BIN_PREFIX=/usr/bin -DRYZOM_GAMES_PREFIX=/usr/bin
  
  make
}

package() {
  cd "$srcdir/build-nel"
  make DESTDIR="$pkgdir" install
  # WWWInit.h is in /usr/include/w3c-libwww according to libwww package!
  sed -ie 's/WWWInit\.h/w3c-libwww\/WWWInit.h/' ${pkgdir}/usr/include/nel/gui/group_html.h
}

# vim:set ts=2 sw=2 et: