# Maintainer (Arch): carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Maintainer: André Silva <emulatorman@parabola.nu>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=reicast-git
pkgver=r1622.826853a
pkgrel=1
pkgdesc="A multiplatform Sega Dreamcast emulator"
arch=('i686' 'x86_64')
url="http://reicast.com/"
license=('GPL2')
conflicts=('reicast')
provides=('reicast')
makedepends=('git')
depends=('libgl' 'alsa-plugins' 'libpulse' 'python-evdev' )
optdepends=('xboxdrv: Userspace gamepad driver for Xbox and Xbox360 gamepads'
            'antimicro: Graphical program used to map keyboard keys and mouse controls to gamepad buttons')
source=(reicast::"git+https://github.com/reicast/reicast-emulator.git"
        'enable_x11_keyboard_support.patch'
        'wait_if_two_frames_already_in_flight.patch')
sha256sums=('SKIP'
            '095961538c13208b39ebb0b9d6b6e30c1225f218dcc67239a9d938a23aec601e'
            '4e087844ed22f5a65348e6826444481e14d0409faf8dafb0c6e5284f3f2bd9f7')

pkgver() {
  cd reicast
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare () {
  cd reicast

  # remove nonfree fp.h header
  rm -v core/deps/libpng/fp.h

  patch -Np1 -i "$srcdir"/enable_x11_keyboard_support.patch
  patch -Np1 -i "$srcdir"/wait_if_two_frames_already_in_flight.patch

  # Add experimental shadow support: http://github.com/reicast-emulator/issues/94
  sed -i 's|//DrawModVols|DrawModVols|' core/rend/gles/gldraw.cpp

  # Fix Xbox Input Axis
  sed -i 's|DC_AXIS_LT, 0, 0, DC_AXIS_RT|0, 0, DC_AXIS_RT, DC_AXIS_LT|' core/linux-dist/joystick.cpp

  # Enable Pulseaudio
  sed -i 's|#USE_PULSEAUDIO|USE_PULSEAUDIO|' shell/linux/Makefile
}

build () {
  make -C reicast/shell/linux
}

package () {
  cd reicast

  make -C shell/linux PREFIX=/usr DESTDIR=$pkgdir install

  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}