# Maintainer: Márcio Silva <coadde@parabola.nu>
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Jon Nordby <jononor@gmail.com>

_pkgname=mypaint
pkgname=('mypaint-gegl-git' 'libmypaint-gegl-git')
pkgver=r4141.ad19153
pkgrel=2
pkgdesc="A fast and easy painting application for digital painters, with brush dynamics and GEGL support"
arch=('i686' 'x86_64' 'armv7h')
url="http://mypaint.intilinux.com/"
license=('GPL' 'LGPL')
depends=('python2-gobject' 'python2-numpy' 'gtk3' 'json-c' 'lcms2' 'gegl')
makedepends=('scons>=0.97' 'swig>=1.3.39' 'git')
source=($_pkgname-$pkgver::git+https://github.com/$_pkgname/$_pkgname
        brushlib::git+https://github.com/$_pkgname/lib$_pkgname)
md5sums=('SKIP'
         'SKIP')

pkgver() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd $srcdir/$_pkgname-$pkgver

  git submodule init
  git config submodule.'brushlib'.url "${srcdir}/brushlib"
  git submodule update

  # python2 fix
  sed -i 's_python generate.py_python2 generate.py_' brushlib/SConscript
  for file in $(find . -name '*.py' -print); do
    sed -i 's_^#!.*/usr/bin/python_#!/usr/bin/python2_' $file
    sed -i 's_^#!.*/usr/bin/env.*python_#!/usr/bin/env python2_' $file
  done
}

package_mypaint-gegl-git() {
  depends=('python2-gobject' 'python2-numpy' 'gtk3' 'lcms2' 'libmypaint-gegl-git')
  provides=("${_pkgname}")
  conflicts=("${_pkgname}")
  install=mypaint.install

  cd $srcdir/$_pkgname-$pkgver
  scons prefix="$pkgdir"/usr use_sharedlib=yes enable_gegl=yes install

  # separate files to libmypaint package
  install -vdm 0755 $srcdir/lib$_pkgname-fakeinstall/usr/{include,lib,share}
  mv -v $pkgdir/usr/include/lib$_pkgname{,-gegl}/*	$srcdir/lib$_pkgname-fakeinstall/usr/include
  mv -v $pkgdir/usr/lib/lib$_pkgname*.so		$srcdir/lib$_pkgname-fakeinstall/usr/lib
  mv -v $pkgdir/usr/lib/pkgconfig			$srcdir/lib$_pkgname-fakeinstall/usr/lib
  mv -v $pkgdir/usr/share/lib$_pkgname			$srcdir/lib$_pkgname-fakeinstall/usr/share
  # mypaint needs libmypaint-tests.so
  install -vDm 0644 brushlib/lib$_pkgname-tests.so	$srcdir/lib$_pkgname-fakeinstall/usr/lib
}

package_libmypaint-gegl-git() {
  _pkgver() {
    cd "${srcdir}/brushlib"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  }
  pkgver=$(_pkgver)
  pkgdesc="A library for making brushstrokes, with GEGL support"
  depends=('python2' 'gcc-libs' 'glib2' 'json-c' 'gegl')
  provides=("lib${_pkgname}")
  conflicts=("lib${_pkgname}" "${_pkgname}<1.2a")

  mv -v $srcdir/lib$_pkgname-fakeinstall/* $pkgdir
}