# $Id: PKGBUILD 87501 2013-04-02 00:06:04Z dreisner $
# Maintainer (Arch): Dave Reisner <d@falconindy.com>
# Maintainer: Esteban Carnevale <alfplayer@mailoo.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=expac
pkgname=expac-relative
pkgver=4
pkgrel=3.parabola1
pkgdesc="pacman database extraction utility, with dbpath and config options support"
arch=('i686' 'x86_64' 'mips64el')
url="http://github.com/falconindy/expac"
license=('GPL')
conflicts=($_pkgname)
provides=($_pkgname)
depends=('pacman')
makedepends=('perl')
source=("http://code.falconindy.com/archive/$_pkgname/$_pkgname-$pkgver.tar.gz"{,.sig}
        '0001-fix-target-processing.patch'
        '0002-conf-always-trim-the-key-name.patch')
md5sums=('5104ad808155e8d2d381d9282caf7bae'
         'SKIP'
         '80433a259a4f5996520f42217b1896b8'
         '879749918e1a4abef4c51e9f870c99e0')

prepare() {
  cd "$_pkgname-$pkgver"

  patch -Np1 < "$srcdir/0001-fix-target-processing.patch"
  patch -Np1 < "$srcdir/0002-conf-always-trim-the-key-name.patch"

  sed '/\*\//q' expac.c >LICENSE
}

build() {
  cd "$_pkgname-$pkgver"

  make
}

package() {
  cd "$_pkgname-$pkgver"

  make PREFIX=/usr DESTDIR="$pkgdir" install

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
}

# vim: ft=sh syn=sh