# $Id$
# Maintainer: André Silva <emulatorman@lavabit.com>

pkgname=debootstrap
pkgver=1.0.48
pkgrel=1
pkgdesc="A tool used to create a gNewSense or Trisquel base system from scratch, without requiring the availability of dpkg or apt"
arch=('any')
license=('GPL')
url="http://packages.debian.org/sid/debootstrap"
depends=('wget')
source=("http://ftp.debian.org/debian/pool/main/d/${pkgname}/${pkgname}_${pkgver}_all.deb"
        'metad'
        'trisquel')
install="debootstrap.install"
md5sums=('f75ae43204ed273c7a95c12a5a2f715a'
         '4425300ca68d60fb60a6d699e153a519'
         'b020aa8426e70a6024c8e76312c17d78')

package(){
  tar -xzf "$srcdir/data.tar.gz" -C "$pkgdir/"

  # doesn't work with gpg 2.x, patch to point to gpg1v
  sed 's/gpgv/gpg1v/g;' -i "$pkgdir/usr/sbin/debootstrap" "$pkgdir/usr/share/debootstrap/functions"

  # add gNewSense script
  install -m644  metad        "$pkgdir/usr/share/debootstrap/scripts"

  # create gNewSense symlinks
  ln -s metad "$pkgdir/usr/share/debootstrap/scripts/deltah"
  ln -s metad "$pkgdir/usr/share/debootstrap/scripts/parkes"

  # add Trisquel script
  install -m644  trisquel        "$pkgdir/usr/share/debootstrap/scripts"

  # create Trisquel symlinks
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/awen"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/brigantia"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/dagda"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/dwyn"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/robur"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/slaine"
  ln -s trisquel "$pkgdir/usr/share/debootstrap/scripts/taranis"
}