# $Id: PKGBUILD 185869 2013-05-19 16:42:53Z foutrelis $
# Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>

_pkgname=pidgin
pkgname=('pidgin-nonprism' 'libpurple-nonprism' 'finch-nonprism')
pkgver=2.10.7
pkgrel=4
arch=('i686' 'x86_64' 'mips64el')
url="http://pidgin.im/"
license=('GPL')
makedepends=('startup-notification' 'gtkspell' 'libxss' 'nss' 'libsasl' 'libsm'
             'libidn' 'python2' 'hicolor-icon-theme' 'farstream-0.1' 'avahi'
             'tk' 'ca-certificates' 'intltool' 'networkmanager')
options=('!libtool')
source=(http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.bz2
        pidgin-2.10.7-link-libirc-to-libsasl2.patch nonprism.patch)
sha256sums=('eba32994eca20d1cf24a4261b059b2de71a1ec2dd0926e904074b0db49f7f192'
            '063723d5dc5726c43137b4b383c9d07c2c008391f6a626faaf6cedd31a2f1e8f'
            '54c185493f7139768e316b989a5d23aa9d46662bf69026a92efbf69ad7d00973')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"
  msg 'remove nonfree services'
  patch -Np1 -i $srcdir/nonprism.patch
  #rm -vrf libpurple/protocols/{gg,jabber/google,msn,mxit,myspace,novell,oscar,yahoo}
  #rm -v pidgin/pixmaps/protocols/16/{aim,facebook,gadu-gadu,google-talk,icq,msn,mxit,myspace,novell,yahoo}.png
  #rm -v pidgin/pixmaps/protocols/16/scalable/{aim,gadu-gadu,icq,msn,novell,yahoo}.svg
  #rm -v pidgin/pixmaps/protocols/22/{aim,facebook,gadu-gadu,google-talk,icq,msn,mxit,myspace,novell,yahoo}.png
  #rm -v pidgin/pixmaps/protocols/22/scalable/{aim,gadu-gadu,icq,msn,novell,yahoo}.svg
  #rm -v pidgin/pixmaps/protocols/48/{aim,facebook,gadu-gadu,icq,msn,mxit,myspace,novell,yahoo}.png
  #rm -v pidgin/pixmaps/protocols/scalable/{aim,gadu-gadu,google-talk,icq,msn,mxit,novell,yahoo}.svg
  msg 'remove wrong OS term'
  sed -i 's|on Linux|on GNU/Linux|' libpurple/valgrind.h
  sed -i 's|On Linux|On GNU/Linux|' libpurple/connection.h
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  # https://developer.pidgin.im/ticket/15517
  patch -Np1 -i "$srcdir/pidgin-2.10.7-link-libirc-to-libsasl2.patch"
  autoreconf -vi

  # Use Python 2
  sed -i 's/env python$/&2/' */plugins/*.py \
    libpurple/purple-{remote,notifications-example,url-handler}

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --disable-schemas-install \
    --disable-meanwhile \
    --disable-gnutls \
    --enable-cyrus-sasl \
    --disable-doxygen \
    --enable-nm \
    --with-python=/usr/bin/python2 \
    --with-system-ssl-certs=/etc/ssl/certs
    make
}

package_pidgin-nonprism(){
  pkgdesc="Multi-protocol instant messaging client"
  depends=('libpurple' 'startup-notification' 'gtkspell' 'libxss' 'libsm'
           'hicolor-icon-theme')
  optdepends=('aspell: for spelling correction')
  provides=("$_pkgname=$pkgver")
  conflicts=$_pkgname
  replaces=$_pkgname
  install=pidgin.install

  cd "$srcdir/pidgin-$pkgver"

  # For linking
  make -C libpurple DESTDIR="$pkgdir" install-libLTLIBRARIES

  make -C pidgin DESTDIR="$pkgdir" install
  make -C doc DESTDIR="$pkgdir" install

  # Remove files that are packaged in libpurle
  make -C libpurple DESTDIR="$pkgdir" uninstall-libLTLIBRARIES

  install -Dm644 pidgin.desktop "$pkgdir"/usr/share/applications/pidgin.desktop

  rm "$pkgdir/usr/share/man/man1/finch.1"
}

package_libpurple-nonprism(){
  pkgdesc="IM library extracted from Pidgin"
  depends=('farstream-0.1' 'libsasl' 'libidn' 'dbus-glib' 'nss')
  optdepends=('avahi: Bonjour protocol support'
              'ca-certificates: SSL CA certificates'
              'python2-dbus: for purple-remote and purple-url-handler'
              'tk: Tcl/Tk scripting support')
  provides=("${pkgname%-nonprism}=$pkgver")
  conflicts=${pkgname%-nonprism}
  replaces=${pkgname%-nonprism}

  cd "$srcdir/pidgin-$pkgver"

  for _dir in libpurple share/sounds share/ca-certs m4macros po; do
    make -C "$_dir" DESTDIR="$pkgdir" install
  done
}

package_finch-nonprism(){
  pkgdesc="A ncurses-based messaging client"
  depends=("libpurple=$pkgver-$pkgrel" 'libx11' 'python2')
  provides=("${pkgname%-nonprism}=$pkgver")
  conflicts=${pkgname%-nonprism}
  replaces=${pkgname%-nonprism}

  cd "$srcdir/pidgin-$pkgver"

  # For linking
  make -C libpurple DESTDIR="$pkgdir" install-libLTLIBRARIES

  make -C finch DESTDIR="$pkgdir" install
  make -C doc DESTDIR="$pkgdir" install

  # Remove files that are packaged in libpurle
  make -C libpurple DESTDIR="$pkgdir" uninstall-libLTLIBRARIES

  rm "$pkgdir"/usr/share/man/man1/pidgin.1
}

# vim:set ts=2 sw=2 et: