# $Id: PKGBUILD 273537 2016-08-09 16:38:33Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
pkgname=kipi-plugins
_pkgver=5.1.0
pkgver=${_pkgver//-/_}
pkgrel=1.parabola1.nonprism1
pkgdesc="Digital photo management application for KDE"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre" "${pkgname}-libre-nonprism")
conflicts=("${pkgname}-libre" "${pkgname}-libre-nonprism")
makedepends=('extra-cmake-modules' 'libkipi' 'libksane' 'liblqr' 'opencv' 'boost'
             'opencv' 'doxygen' 'lensfun' 'eigen' 'kdoctools' 'marble' 'kdesignerplugin'
             'kfilemetadata' 'akonadi-contact' 'qt5-multimedia' 'threadweaver' 'kcalcore'
             'knotifyconfig' 'libmediawiki' 'libkvkontakte')
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${_pkgver}.tar.xz"
        "digikam-5.1-fix-build.patch"
        "libre.patch"
        "nonprism.patch")
sha1sums=('87a843c39f45b8704ead6e6029e52fb03ee44680'
          '5b6644c8b5534a1712f46fc84948de9a0039a601'
          'ed2a01c4a837b50d3c1ad0d4758f2fa3bb44402f'
          '3e0f11296e887171c4f5f05652bb0ea635b021fd')

prepare() {
  mkdir -p build

  cd ${pkgbase}-${_pkgver}
  patch -p1 -i ../libre.patch
  patch -p1 -i ../nonprism.patch

  # Fix build on i686
  patch -p1 -i ../digikam-5.1-fix-build.patch
}

build() {
  cd build

  cmake ../${pkgbase}-${_pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_TESTING=OFF \
    -DENABLE_KFILEMETADATASUPPORT=ON \
    -DENABLE_MEDIAPLAYER=ON \
    -DENABLE_AKONADICONTACTSUPPORT=ON \
    -DENABLE_MYSQLSUPPORT=ON \
    -DDIGIKAMSC_COMPILE_LIBKVKONTAKTE=OFF \
    -DENABLE_OPENCV3=ON
  make
}

package_kipi-plugins() {
  pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree suggestions and support for unsafe and dangerous for privacy protocols"
  depends=('kio' 'libkipi')
  optdepends=('libmediawiki: MediaWiki Export plugin')

  cd build/extra
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/doc/kipi-plugins
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/doc-translated/kipi-plugins
  make DESTDIR="pkgdir" install
  cd $srcdir/build/po
  make DESTDIR="$pkgdir" install

# Provided by digikam
  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
}