# $Id: PKGBUILD 225564 2014-11-03 12:36:10Z ronald $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
pkgname=kipi-plugins
pkgver=4.4.0
pkgrel=1.parabola1.nonprism1
pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree jAlbum and SimpleViewer support and support for unsafe and dangerous for privacy protocols"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre" "${pkgname}-libre-nonprism")
conflicts=("${pkgname}-libre" "${pkgname}-libre-nonprism")
makedepends=('kdepimlibs' 'libkexiv2' 'libkdcraw' 'libkipi' 'libksane' 'liblqr'
             'kdeedu-marble' 'opencv' 'boost' 'libgpod' 'qjson' 'hugin' 'libgphoto2'
             'cmake' 'automoc4' 'doxygen' 'lensfun' 'qt-gstreamer' 'imagemagick' 'eigen')
depends=('kdebase-runtime' 'kdepimlibs' 'libkdcraw' 'libkipi' 'libksane' 'libkexiv2')
optdepends=('libkgeomap: Geolocalize tool'
            'libmediawiki: MediaWiki Export plugin'
            'libgpod: iPodExport plugin'
            'opencv: Remove Red Eyes plugin'
            'imagemagick: Video SlideShow plugin'
            'qt-gstreamer: Video SlideShow plugin')
options=('staticlibs')
install=kipi-plugins.install
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.bz2" "digikam_libkexiv2.patch")
sha1sums=('1feb43120addda314e09761440ec2058e430171c'
          '39a09a8e7de1612eb47f3ef0966c6fa02b7e3284')

prepare() {
  cd ${srcdir}/${pkgbase}-${pkgver}
  sed -i '\|flashexport|d
          \|jalbumexport|d
          \|imageshackexport|d
          s| Facebook, and Imgur||
          \|QtKOAuth|d
          \|Imgur|d
          \|imgurexport|d
          \|LIBKVKONTAKTE|d
          \|vkontakte|d
          s| and YandexFotki||
          \|YandexFotki|d
          \|yandexfotki|d
          \|DlnaExport|d
          \|dlnaexport|d
          \|Facebook|d
          \|facebook|d
          \|flickrexport|d
          \|picasawebexport|d
         ' extra/kipi-plugins/CMakeLists.txt
  sed -i '\|m_actionExport| s|true|false|
         ' extra/kipi-plugins/smug/plugin_smug.cpp
  sed -i '\|Remote Flickr Export plugin|,+2 d
          \|flickrexport|d
         ' doc/kipi-plugins/index.docbook
  cd ..
  mkdir build
  cd ${pkgbase}-${pkgver}/core
  patch -Np1 -i "${srcdir}/digikam_libkexiv2.patch"
}

build() {
  cd build
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_tests=OFF \
    -DDIGIKAMSC_USE_PRIVATE_KDEGRAPHICS=OFF
  make
}

package() {
  cd build/extra/kipi-plugins
  make DESTDIR="${pkgdir}" install

  cd ../../../build/po
  make DESTDIR="${pkgdir}" install
  # Put these in the relevant splitted packages
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkgeomap.mo
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/digikam.mo
  # Fix conflicts with kde-l10n-* (FS#33762)
  rm "${pkgdir}"/usr/share/locale/kde4/*/LC_MESSAGES/libkipi.mo
}