# $Id: PKGBUILD 267261 2016-05-09 19:41:11Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=gnome-weather
pkgver=3.20.1
pkgrel=1.nonprism1
pkgdesc="Access current weather conditions and forecasts, without geoclue2 support"
url="https://wiki.gnome.org/Apps/Weather"
arch=(any)
license=(GPL)
depends=(gtk3 gjs libgweather)
makedepends=(intltool gobject-introspection)
groups=(gnome-extra)
source=(http://ftp.gnome.org/pub/GNOME/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz
        nonprism.patch)
sha256sums=('e310ecd56f396ac0e8e5652ac8b63258720034e23afbf32fbb2d509f25bbb2b6'
            '67daef24d0aaf285d1f2960d5f3b976e71e5150233468a738cdd7557ee730fa4')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 -i $srcdir/nonprism.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}