# $Id: PKGBUILD 226152 2014-11-12 21:58:04Z heftig $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=gnome-online-accounts
pkgver=3.14.2
pkgrel=1.nonprism1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64 mips64el)
url="http://www.gnome.org"
license=('GPL')
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
depends=('webkitgtk' 'json-glib' 'libnotify' 'rest' 'libsecret' 'telepathy-glib' 'krb5' 'gcr')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl' 'python2')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('341a2c79cd26770ccbf4476f7ce7222cfe026f442cfbd05dc7f7612f7b30dae9')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --libexecdir=/usr/lib/$pkgname --disable-static \
    --disable-exchange --disable-facebook -disable-flickr \
    --disable-google --enable-imap-smtp --disable-kerberos \
    --enable-owncloud --disable-pocket --enable-telepathy \
    --disable-windows-live --disable-twitter --disable-yahoo
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: