# $Id: PKGBUILD 262506 2016-03-24 23:12:19Z jgc $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=gnome-online-accounts
pkgver=3.20.0
pkgrel=1.nonprism1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64)
url="http://www.gnome.org"
license=('GPL')
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
depends=('webkit2gtk' 'json-glib' 'libnotify' 'rest' 'libsecret' 'telepathy-glib' 'krb5' 'gcr')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl')
optdepends=('gvfs-goa: Virtual file systems (e.g. OwnCloud)')
install=$pkgname.install
source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('c98233914c455dc21f8c73904dd2881bee6bfa117a5bdc573ba3a8550c36a460')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --libexecdir=/usr/lib/$pkgname --disable-static \
    --disable-exchange --disable-facebook -disable-flickr \
    --disable-google --enable-imap-smtp --disable-kerberos \
    --enable-owncloud --disable-pocket --enable-telepathy \
    --disable-windows-live --disable-twitter --disable-yahoo \
    --enable-media-server --disable-foursquare --enable-lastfm
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make -j1 DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: