# $Id: PKGBUILD 193763 2013-08-30 13:15:23Z heftig $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=gnome-online-accounts
pkgname=gnome-online-accounts-nonprism
pkgver=3.8.3
pkgrel=1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64 mips64el)
url="http://www.gnome.org"
license=('GPL')
depends=('webkitgtk3' 'json-glib' 'libnotify' 'rest' 'hicolor-icon-theme' 'libsecret')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl')
provides=("$_pkgname=$pkgver")
conflicts=$_pkgname
replaces=($_pkgname $pkgname-coherence)
options=(!libtool)
install=$_pkgname.install
source=(http://download.gnome.org/sources/$_pkgname/${pkgver:0:3}/$_pkgname-$pkgver.tar.xz)
sha256sums=('9e5e55c5097b8d7c32c0dfb7d94448795c627723b133e8edd0b846adde63a44b')
 
build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --libexec=/usr/lib/gnome-online-accounts \
    --disable-google \
    --enable-owncloud \
    --disable-facebook \
    --disable-windows-live \
    --disable-exchange \
    --disable-flickr \
    --enable-imap-smtp \
    --disable-kerberos
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: