# $Id: PKGBUILD 266669 2016-04-29 23:03:36Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=evolution-data-server
pkgver=3.20.1
pkgrel=2.nonprism1
pkgdesc="Centralized access to appointments and contacts, without libgdata support"
arch=(i686 x86_64)
depends=(gnome-online-accounts nss krb5 libgweather libical db libphonenumber webkitgtk)
makedepends=(intltool gperf gobject-introspection vala gtk-doc boost)
install=$pkgname.install
url="https://wiki.gnome.org/Apps/Evolution"
license=(GPL)
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism")
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('1dfbf6b45656c202f3d68212afb11710e40188db84748d3e487a89ccd4874b53')

build() {
  cd "$pkgname-$pkgver"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --with-openldap=yes \
      --libexecdir=/usr/lib/evolution-data-server \
      --with-krb5=/usr --with-libdb=/usr --with-phonenumber=/usr \
      --without-libgdata \
      --disable-google \
      --enable-vala-bindings --disable-uoa \
      --enable-gtk-doc
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd "$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install
}