# $Id: PKGBUILD 196609 2013-10-15 18:22:34Z heftig $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

_pkgname=eog-plugins
pkgname=eog-plugins-nonprism
pkgver=3.10.1
pkgrel=1
pkgdesc="Plugins for Eye of Gnome, without libgdata support"
arch=('i686' 'x86_64')
url="http://www.gnome.org/"
license=('GPL2')
depends=('eog' 'libchamplain')
makedepends=('intltool')
provides=("$_pkgname=$pkgver")
conflicts=$_pkgname
replaces=$_pkgname
install=eog-plugins.install
options=('!libtool')
source=(http://download.gnome.org/sources/$_pkgname/${pkgver%.*}/$_pkgname-$pkgver.tar.xz)
sha256sums=('d5b32c49dbf1e0b6cf56c9fdc6c19186c92e98d92b71aa98805491e2bb2f8e12')

build() {
  cd $_pkgname-$pkgver
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
    --sysconfdir=/etc --localstatedir=/var

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: