# $Id: PKGBUILD 249326 2015-10-14 14:29:56Z heftig $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=empathy
pkgver=3.12.11
pkgrel=1.nonprism1
pkgdesc="A GNOME instant messaging client using the Telepathy framework, without geoclue2 support"
arch=(i686 x86_64)
url="http://live.gnome.org/Empathy"
license=(GPL2)
depends=(clutter-gst2 clutter-gtk folks gcr iso-codes libcanberra libpulse webkitgtk
         telepathy-farstream telepathy-glib telepathy-logger telepathy-mission-control
         geocode-glib cheese libchamplain libgudev)
makedepends=(intltool itstool docbook-xsl python2)
optdepends=('telepathy-gabble: XMPP/Jabber support'
            'telepathy-idle: IRC support'
            'telepathy-salut: Link-local XMPP support'
            'telepathy-rakia: SIP support'
            'telepathy-haze: libpurple support')
options=('!makeflags')
groups=(gnome)
install=empathy.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('d1e4ff4e5f502b7f4ca2c6140462bad2a712b82f019aea4e0a2700e77545d487')

build() {
  cd $pkgname-$pkgver
  PYTHON=/usr/bin/python2 ./configure --prefix=/usr \
      --sysconfdir=/etc  \
      --libexecdir=/usr/lib/empathy \
      --disable-static \
      --enable-location=no
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}