# $Id: PKGBUILD 128521 2015-03-02 10:59:26Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch):  Christian Himpel <chressie at gmail dot com>
# Contributor (Arch): Johannes Hanika <hanatos at gmail dot com>

pkgname=darktable
pkgver=1.6.3
pkgrel=1.nonprism1
pkgdesc="Utility to organize and develop raw images, without flickcurl support"
arch=('i686' 'x86_64' 'mips64el')
url=http://darktable.sf.net/
license=('GPL3')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('exiv2>=0.18' 'intltool>=0.40' 'lcms2' 'lensfun>=0.2.3' 'libglade' 'dbus-glib'
	 'curl' 'libsecret' 'libgphoto2' 'openexr' 'sqlite' 'libxslt'
	 'libsoup' 'gtk-engines' 'json-glib' 'lua')
makedepends=('intltool>=0.40' 'cmake' 'librsvg')
optdepends=('librsvg')
install=darktable.install
source=("$pkgname-$pkgver.tar.gz::https://github.com/darktable-org/darktable/archive/release-$pkgver.tar.gz")
md5sums=('631eec1dfa2071bbb56156d99ed164c2')

prepare() {
  cd "$srcdir/$pkgname-release-$pkgver/cmake"
  sed "s|@PROJECT_VERSION@|$pkgver|" version.cmake.cmake >version.cmake
}

build() {
  cd "$srcdir/$pkgname-release-$pkgver"
  mkdir -p build
  cd build
  CXXFLAGS+=" -fpermissive"
  cmake \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DCMAKE_BUILD_TYPE=Release \
      -DDONT_INSTALL_GCONF_SCHEMAS=True \
      -DBINARY_PACKAGE_BUILD=1 \
      -DUSE_GCONF_BACKEND=Off \
      -DBUILD_USERMANUAL=False \
      -DUSE_LIBSECRET=On \
      -DUSE_LUA=On \
      -DUSE_GNOME_KEYRING=Off \
      -DUSE_USE_FLICKR=Off \
      ..
  make
}

package() {
  cd "$srcdir/$pkgname-release-$pkgver/build"
  make DESTDIR="$pkgdir" install
  mv "${pkgdir}/usr/share/doc/darktable" "${pkgdir}/usr/share/doc/${pkgname}-${pkgver}"
}