# Maintainer: Figue <ffigue at gmail>
# Contributor: Figue <ffigue at gmail>
# Contributor (Parabola): fauno <fauno@kiwwwi.com.ar>
# Contributor (Parabola): vando <facundo@esdebian.org>
# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com> 

# If you are updating this package, don't forget to update the version number in
# the value for 'browser.dictionaries.download.url' in 'libre.patch'

pkgname=icecat
_pkgver=9.0
pkgver=9.0.1
pkgrel=1
pkgdesc="The GNUzilla web browser, based on Mozilla Firefox. SafeBrowsing and other Google services disabled!"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.gnu.org/software/gnuzilla/"
license=('MPL' 'GPL' 'LGPL')
depends=(
  'alsa-lib'
  'dbus-glib'
  'desktop-file-utils'
  'gtk2'
  'hicolor-icon-theme'
  'hunspell'
  'libevent'
  'libnotify'
  'libvpx'
  'libxt'
  'mime-types'
  'mozilla-common'
  'mozilla-searchplugins'
  'nss'
  'sqlite3'
  'startup-notification'
)
makedepends=(
  'autoconf2.13'
  'diffutils'
  'libidl2'
  'mesa'
  'p7zip-libre'
  'pkg-config'
  'python2'
  'wireless_tools'
  'xorg-server-xvfb'
  'yasm'
  'zip'
)
options=(!buildflags !distcc)
install=icecat.install
source=(ftp://ftp.gnu.org/gnu/gnuzilla/${pkgver}/${pkgname}-${pkgver}.tar.xz
        mozconfig
	mozconfig.old
	mozconfig.default
	libre.patch
	parabola.patch
        icecat.desktop
        icecat-safe.desktop)

build() {
  ICECATDIR="/usr/lib/${pkgname}-${_pkgver}" && export ICECATDIR
  cd "${srcdir}/${pkgname}-${pkgver}"

  cp "$srcdir/mozconfig" .mozconfig # Load our build config, disable SafeSearch
  patch -Np1 -i "$srcdir/libre.patch" # Remove Google+Mozilla stuff
  patch -Np1 -i "$srcdir/parabola.patch" # Parabola settings

  # Fix PRE_RELEASE_SUFFIX
  sed -i '/^PRE_RELEASE_SUFFIX := ""/s/ ""//' browser/base/Makefile.in

  export LDFLAGS="$LDFLAGS -Wl,-rpath,$ICECATDIR"
  export PYTHON="/usr/bin/python2"

  LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
  LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS="$MAKEFLAGS"
  kill $! || true
}

package() {
  ICECATDIR="/usr/lib/${pkgname}-${_pkgver}" && export ICECATDIR
  cd "${srcdir}/${pkgname}-${pkgver}"

  make -j1 -f client.mk DESTDIR="$pkgdir" install

  msg2 "Finishing..."
  install -m755 -d                                        "${pkgdir}/usr/share/pixmaps"
  install -m644 browser/branding/unofficial/default48.png "${pkgdir}/usr/share/pixmaps/${pkgname}.png"

  install -m755 -d                              "${pkgdir}/usr/share/applications"
  install -m644 "${srcdir}/icecat.desktop"      "${pkgdir}/usr/share/applications"
  install -m644 "${srcdir}/icecat-safe.desktop" "${pkgdir}/usr/share/applications"

  ln -s "${pkgname}-${pkgver}" "${pkgdir}/usr/lib/${pkgname}-${_pkgver}" # WHY???!!!
  ln -s "${pkgname}-${_pkgver}" "${pkgdir}/usr/lib/${pkgname}"

  rm -rf "${pkgdir}${ICECATDIR}/"{dictionaries,hyphenation,searchplugins,plugins}
  ln -sf /usr/share/hunspell            "${pkgdir}${ICECATDIR}/dictionaries"
  ln -sf /usr/share/hyphen              "${pkgdir}${ICECATDIR}/hyphenation"
  ln -sf /usr/lib/mozilla/plugins       "${pkgdir}${ICECATDIR}/plugins"
  ln -sf /usr/lib/mozilla/searchplugins "${pkgdir}${ICECATDIR}/searchplugins"

  # We don't want the development stuff
  rm -rf "${pkgdir}/usr/include"
  rm -rf "${pkgdir}/usr/lib/${pkgname}-devel-${pkgver}"
  rm -rf "${pkgdir}/usr/share/idl"

  # Workaround for now:
  #  https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf "${ICECATDIR}/${pkgname}-bin" "${pkgdir}${ICECATDIR}/$pkgname"
}

md5sums=('a135581da2fd2845f268d7ca91054c06'
         '9c0cd5b45a3c4b04b872b6a900f62286'
         '0e5057d9427c6cd5e2f3b78fe34f50d9'
         '44959606e4a704e68a913e73fc941926'
         '07e65752416e615fe04ce586bc58f86b'
         '037b44b6e07d7115e0fb221d67b94272'
         'e81ad01dbc16ba28bf92ba4b7c309ca7'
         'd93fe402b87cd000a869e1fd6badc6c9')