# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Figue <ffigue at gmail>
# Contributor (Parabola): fauno <fauno@kiwwwi.com.ar>
# Contributor (Parabola): vando <facundo@esdebian.org>
# Contributor (Arch): Jakub Schmidtke <sjakub@gmail.com>
# Thank you very much to the older contributors:
# Contributor: evr <evanroman at gmail>
# Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com> 

# If you are updating this package, don't forget to update the version number in
# the value for 'browser.dictionaries.download.url' in 'libre.patch'

pkgname=icecat
pkgver=9.0.1
pkgrel=2
pkgdesc="The GNUzilla web browser, based on Mozilla Firefox. SafeBrowsing and other Google services disabled!"
arch=('i686' 'x86_64' 'mips64el')
license=('MPL' 'GPL' 'LGPL')
depends=(
  'alsa-lib'
  'dbus-glib'
  'desktop-file-utils'
  'gtk2'
  'hicolor-icon-theme'
  'hunspell'
  'libevent'
  'libnotify'
  'libvpx'
  'libxt'
  'mime-types'
  'mozilla-common'
  'mozilla-searchplugins'
  'nss>=3.13.1'
  'sqlite3'
  'startup-notification'
)
makedepends=(
  'autoconf2.13'
  'diffutils'
  'libidl2'
  'mesa'
  'p7zip-libre'
  'pkg-config'
  'python2'
  'wireless_tools'
  'xorg-server-xvfb'
  'yasm'
  'zip'
)
url="http://www.gnu.org/software/gnuzilla/"
install=icecat.install
source=(ftp://ftp.gnu.org/gnu/gnuzilla/${pkgver}/${pkgname}-${pkgver}.tar.xz
        mozconfig
        icecat.desktop
        icecat-safe.desktop
        libre.patch
        firefox-install-dir.patch
        vendor.js)

build() {
  cd "$srcdir/$pkgname-$pkgver"

  cp "$srcdir/mozconfig" .mozconfig # Load our build config, disable SafeSearch
  patch -Np1 -i "$srcdir/firefox-install-dir.patch" # install to /usr/lib/$pkgname
  patch -Np1 -i "$srcdir/libre.patch" # Remove Google+Mozilla stuff

  # Fix PRE_RELEASE_SUFFIX
  sed -i '/^PRE_RELEASE_SUFFIX := ""/s/ ""//' \
    browser/base/Makefile.in

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/$pkgname"
  export PYTHON="/usr/bin/python2"

  LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
  LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS="$MAKEFLAGS"
  kill $! || true
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make -j1 -f client.mk DESTDIR="$pkgdir" install

  install -m644 "$srcdir"/vendor.js "$pkgdir/usr/lib/$pkgname/defaults/pref"

  brandingdir="browser/branding/unofficial"
  for i in 16x16 32x32 48x48; do
    install -Dm644 "$brandingdir/default${i/x*/}.png" "$pkgdir/usr/share/icons/hicolor/$i/apps/$pkgname.png"
  done

  install -d                                  "$pkgdir/usr/share/applications"
  install -m644 "$srcdir/icecat.desktop"      "$pkgdir/usr/share/applications"
  install -m644 "$srcdir/icecat-safe.desktop" "$pkgdir/usr/share/applications"

  rm -rf "$pkgdir/usr/lib/$pkgname/"{dictionaries,hyphenation,searchplugins,plugins}
  ln -sf /usr/share/hunspell            "$pkgdir/usr/lib/$pkgname/dictionaries"
  ln -sf /usr/share/hyphen              "$pkgdir/usr/lib/$pkgname/hyphenation"
  ln -sf /usr/lib/mozilla/plugins       "$pkgdir/usr/lib/$pkgname/plugins"
  ln -sf /usr/lib/mozilla/searchplugins "$pkgdir/usr/lib/$pkgname/searchplugins"

  # We don't want the development stuff
  rm -rf "$pkgdir"/usr/{include,lib/$pkgname-devel,share/idl}

  # Fix a bug with https-everywhere (duplicate rules)
  rm -f "$pkgdir/usr/lib/$pkgname/extensions/https-everywhere@eff.org/chrome/content/rules/GoogleMaps.xml~HEAD"

  # Workaround for now: https://bugzilla.mozilla.org/show_bug.cgi?id=658850
  ln -sf $pkgname "$pkgdir/usr/lib/$pkgname/$pkgname-bin"
}

md5sums=('a135581da2fd2845f268d7ca91054c06'
         '9c0cd5b45a3c4b04b872b6a900f62286'
         '0e5057d9427c6cd5e2f3b78fe34f50d9'
         '44959606e4a704e68a913e73fc941926'
         'e81ad01dbc16ba28bf92ba4b7c309ca7'
         'd93fe402b87cd000a869e1fd6badc6c9'
         '07e65752416e615fe04ce586bc58f86b'
         '1e4bcac59e93d21fffa6a1d1ad235247'
         '0d053487907de4376d67d8f499c5502b')
md5sums=('a135581da2fd2845f268d7ca91054c06'
         '9c0cd5b45a3c4b04b872b6a900f62286'
         'e81ad01dbc16ba28bf92ba4b7c309ca7'
         'd93fe402b87cd000a869e1fd6badc6c9'
         '07e65752416e615fe04ce586bc58f86b'
         '1e4bcac59e93d21fffa6a1d1ad235247'
         'c382e35315047e4ca368d09383b39b8d')