# $Id: PKGBUILD 177534 2013-02-07 02:39:51Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=xscreensaver
pkgname=xscreensaver-libre
pkgver=5.21
pkgrel=1
pkgdesc="Screen saver and locker for the X Window System, without nonfree asm files"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.jwz.org/xscreensaver/"
license=('BSD')
depends=('libxxf86vm' 'libglade' 'glu' 'xorg-appres' 'libxmu' \
         'perl-libwww' 'perl-http-message')
makedepends=('bc' 'libxpm' 'gdm' 'mesa')
optdepends=('gdm: for login manager support')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
backup=('etc/pam.d/xscreensaver')
source=(http://www.jwz.org/xscreensaver/${_pkgname}-${pkgver}.tar.gz \
        add-electricsheep.diff xscreensaver.pam LICENSE)
sha1sums=('cc44ddc538ad5b59ff851f70e8a48633763ff077'
          '677496218b81a42d90bee400026e94dd87fb8ffb'
          '106635aa1aae51d6f0668b1853f6c49a4fe9d3d8'
          '4209ea586b204fd1d81c382a0522c654f9fd9134')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  patch -p0 -i "${srcdir}/add-electricsheep.diff"
  
  # Deleting dmsc.asm file due that don't have source code supplied
  rm -v hacks/images/m6502/dmsc.asm

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib --with-x-app-defaults=/usr/share/X11/app-defaults \
    --with-pam --with-login-manager --with-gtk --with-gl \
    --without-gle --with-pixbuf --with-jpeg
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make install_prefix="${pkgdir}" install
  install -D -m644 ../LICENSE "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
  install -D -m644 ../xscreensaver.pam "${pkgdir}/etc/pam.d/xscreensaver"
  chmod 755 "${pkgdir}/usr/bin/xscreensaver"
  echo "NotShowIn=KDE;GNOME;" >> "${pkgdir}/usr/share/applications/xscreensaver-properties.desktop"
}