# $Id: PKGBUILD 110797 2014-05-07 10:38:28Z bpiotrowski $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Brad Fanella <bradfanella@archlinux.us>
# Contributor: [vEX] <niechift.dot.vex.at.gmail.dot.com>
# Contributor: Zeqadious <zeqadious.at.gmail.dot.com>
# Contributor: BlackIkeEagle < ike DOT devolder AT gmail DOT com >
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_prefix=/usr

_pkgname=xbmc
pkgname=xbmc-libre
pkgver=13.0
_codename=Gotham
pkgrel=2.1
pkgdesc="A software media player and entertainment hub for digital media (Gotham version), without nonfree addons and unrar support"
arch=('i686' 'x86_64')
url="http://xbmc.org"
license=('GPL' 'custom')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('hicolor-icon-theme' 'fribidi' 'lzo2' 'smbclient' 'libtiff' 'libva'
         'libpng' 'libcdio' 'yajl' 'libmysqlclient' 'libjpeg-turbo' 'libsamplerate'
         'glew' 'libssh' 'libmicrohttpd' 'libxrandr' 'sdl_mixer' 'sdl_image'
         'python2' 'libass' 'libmpeg2' 'libmad' 'libmodplug' 'jasper' 'rtmpdump'
         'unzip' 'mesa-demos' 'xorg-xdpyinfo' 'libbluray' 'libnfs' 'afpfs-ng'
         'avahi' 'bluez-libs' 'tinyxml' 'libcap' 'swig' 'taglib' 'libpulse'
         'java-runtime-headless' 'glu' 'mesa' 'shairplay' 'libxslt' 'ffmpeg')
makedepends=('boost' 'cmake' 'gperf' 'nasm' 'libxinerama' 'zip' 'libvdpau' 'libcec'
      'udisks' 'upower' 'mesa' 'doxygen' 'swig' 'java-environment')
optdepends=('libcec: support for Pulse-Eight USB-CEC adapter'
      'lirc: remote controller support'
      'udisks: automount external drives'
      'upower: used to trigger power management functionality'
      'xorg-xinit: autostart xbmc'
      'pulseaudio: for pulseaudio support')
install="${_pkgname}.install"
mksource=(
  "xbmc-$pkgver.tar.gz::https://github.com/xbmc/xbmc/archive/13.0-Gotham.tar.gz"
  )
source=(
  "https://repo.parabolagnulinux.org/other/$pkgname/$pkgname-$pkgver.tar.gz"
  "xbmc.service"
  "polkit.rules"
  "enable-external-ffmpeg.patch"
  )
mkmd5sums=('54fafd985b5209859ba6faeb50b8f142')
md5sums=('87083f6d9be2861dfc8bddca959e3880'
         'de331663cc8adc94f2fe44a262cfff58'
         '02f7951824ee13103344f36009c0ef2a'
         '9f9b41cfc1e21b1e7d0bb10d6e85b3c6')

mksource() {
  cd "${srcdir}/xbmc-$pkgver-$_codename"

  msg2 "remove nonfree unRAR utility files from the source"
  rm -rv lib/UnrarXLib
}

prepare() {
  cd "${srcdir}/xbmc-$pkgver-$_codename"
  patch -p1 -i ../enable-external-ffmpeg.patch

  msg2 "Use addons.xml from Parabola server (without nonfree addons support)"
  sed -i -e 's|mirrors[.]xbmc[.]org/addons/gotham/addons.xml|repo.parabolagnulinux.org/other/xbmc-libre/addons/gotham/addons.xml|' addons/repository.xbmc.org/addon.xml
}

build() {
  cd "${srcdir}/xbmc-$pkgver-$_codename"

  # Bootstrapping XBMC
  ./bootstrap

  # Configuring XBMC
  export PYTHON_VERSION=2  # external python v2
  ./configure --prefix=$_prefix --exec-prefix=$_prefix \
    --disable-debug \
    --enable-optimizations \
    --enable-gl \
    --enable-sdl \
    --enable-vaapi \
    --enable-vdpau \
    --enable-xvba \
    --enable-joystick \
    --enable-xrandr \
    --enable-rsxs \
    --enable-projectm \
    --enable-x11 \
    --enable-rtmp \
    --enable-samba \
    --enable-nfs \
    --enable-afpclient \
    --enable-airplay \
    --enable-airtunes \
    --enable-ffmpeg-libvorbis \
    --enable-dvdcss \
    --disable-hal \
    --enable-avahi \
    --enable-webserver \
    --enable-optical-drive \
    --enable-libbluray \
    --enable-texturepacker \
    --enable-udev \
    --enable-libusb \
    --enable-libcec \
    --enable-external-libraries \
    --disable-non-free

  # Now (finally) build
  make
}

package() {
  cd "${srcdir}/xbmc-$pkgver-$_codename"
  # Running make install
  make DESTDIR="${pkgdir}" install

  # run feh with python2
  sed -i -e 's/python/python2/g' ${pkgdir}${_prefix}/bin/xbmc

  # Tools
  msg2 "Tools"
  install -D -m 0755 "${srcdir}/xbmc-$pkgver-$_codename/xbmc-xrandr" "${pkgdir}${_prefix}/share/xbmc/xbmc-xrandr"
  install -D -m 0755 "${srcdir}/xbmc-$pkgver-$_codename/tools/TexturePacker/TexturePacker" "${pkgdir}${_prefix}/share/xbmc/"

  # Licenses
  msg2 "Copy licenses"
  install -dm755 ${pkgdir}${_prefix}/share/licenses/${_pkgname}
  for licensef in LICENSE.GPL copying.txt; do
    mv ${pkgdir}${_prefix}/share/doc/xbmc/${licensef} \
      ${pkgdir}${_prefix}/share/licenses/${_pkgname}
  done

  # install systemd service
  install -Dm0644 $srcdir/xbmc.service $pkgdir/usr/lib/systemd/system/xbmc.service
  install -Dm0644 $srcdir/polkit.rules $pkgdir/etc/polkit-1/rules.d/10-xbmc.rules
}
# vim:set ts=2 sw=2 et: