# $Id: PKGBUILD 105928 2014-02-19 11:27:15Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Alexander Fehr <pizzapunk gmail com>
# Contributor: Andrew Simmons <andrew.simmons@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=xarchiver
pkgname=xarchiver-libre
pkgver=0.5.3
pkgrel=1
pkgdesc="GTK+ frontend to various command line archivers, with unar support"
arch=('i686' 'x86_64' 'mips64el')
url="http://xarchiver.sourceforge.net/"
license=('GPL')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
replaces=("$_pkgname")
depends=('gtk2' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('zip: ZIP support'
            'unzip: ZIP support'
            'p7zip: 7z support'
            'arj: ARJ support'
            'lzop: LZOP support'
            'cpio: RPM support'
            'unar: RAR support')
install=xarchiver.install
source=(http://downloads.sourceforge.net/xarchiver/xarchiver-$pkgver.tar.bz2
        xarchiver-0.5.3-fix-rpm-support.patch
        xarchiver-0.5.3-fix-double-escaping.patch
        xarchiver-0.5.3-fix-password-protected.patch
        xarchiver-0.5.3-add-mime-types.patch
        xarchiver-0.5.3-add-unar-support.patch)
md5sums=('fd390bbd2df76a5f8a007bdeae82d4aa'
         '812b93339f5e3332621f3c5abebfe277'
         '6178d7ab679b761469c880a8db991907'
         '35ab96d98521a0a36f3e9e9ec0969107'
         'f9119f5290caa195a56b7d3c63d9137d'
         '5f0b21efd0159d41f207e664b72210b8')

prepare() {
  cd $_pkgname-$pkgver

  # Fix RPM support
  patch -Np1 -i ../xarchiver-0.5.3-fix-rpm-support.patch

  # Fix error when trying to create archives with spaces
  patch -Np1 -i ../xarchiver-0.5.3-fix-double-escaping.patch

  # Fix segfault when handling password protected files
  patch -Np1 -i ../xarchiver-0.5.3-fix-password-protected.patch

  # Add more MIME types in the desktop file
  patch -Np1 -i ../xarchiver-0.5.3-add-mime-types.patch

  # Add unar support
  patch -Np1 -i ../xarchiver-0.5.3-add-unar-support.patch
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --libexecdir=/usr/lib/xfce4
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}