# $Id: PKGBUILD 113127 2014-06-13 22:30:55Z arodseth $
# Maintainer (Arch): Alexander Rødseth <rodseth@gmail.com>
# Contributor (Arch): kappa <kappacurve@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

_name=wings
pkgname=wings3d
pkgver=1.5.3
pkgrel=1.parabola1
pkgdesc='3D modeling program, without nonfree kerkythea render support'
arch=('x86_64' 'i686' 'mips64el')
url='http://www.wings3d.com/'
license=('GPL')
depends=('erlang-sdl' 'erlang-cl' 'bash' 'desktop-file-utils' 'erlang')
makedepends=('gendesk')
optdepends=('povray: rendering support via POV-Ray')
conflicts=("${pkgname}-libre")
replaces=("${pkgname}-libre")
install=$pkgname.install
source=("http://downloads.sourceforge.net/project/wings/wings/$pkgver/wings-$pkgver.tar.bz2"
        "$pkgname.sh"
        "$pkgname.png::http://img299.imageshack.us/img299/2538/wingsiconblackshiningew5.png")
sha256sums=('c08060016f83679ce08947942d31af0e3b5d105525d0df5e993ec6f1a81fdd8e'
            '46513cd05f8b6e778120af4a87b239c5250799c17b591592893d98cbf082359e'
            '6658977cc3bc8db2c9358edf3a2d6cb6bb8084c9a1d96ca573a83dd4e8781f1a')

prepare() {
  gendesk -f --pkgname "$pkgname" --pkgdesc "$pkgdesc" --name 'Wings3D' \
    --genericname '3D Modeler' --categories 'Graphics;3DGraphics'
}

build() {
  export ESDL_PATH=$(echo /usr/lib/erlang/lib/esdl-*)
  make -C "$_name-$pkgver" all lang
}

package() {
  install -Dm644 "$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"
  install -Dm644 "$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm755 "$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  cd "$_name-$pkgver"
  install -d "$pkgdir/usr/lib/$pkgname"
  for subdir in ebin fonts patches plugins shaders textures; do
    cp -r "$srcdir/$_name-$pkgver/$subdir/" "$pkgdir/usr/lib/$pkgname"
  done
  msg 'remove nonfree kerkythea render support plugin'
  rm -v $pkgdir/usr/lib/$pkgname/plugins/import_export/wpc_kerky.beam

  msg 'remove deprecated yafray render support plugin'
  rm -v $pkgdir/usr/lib/$pkgname/plugins/import_export/wpc_yafray{.beam,_{de,en,fr,ko}.lang}
}

# vim:set ts=2 sw=2 et: