# $Id: PKGBUILD 90212 2013-05-09 00:26:24Z seblu $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
# Maintainer: Sébastien Luttringer <seblu@archlinux.org>
# Maintainer (Parabola): Jorge López <jorginho@lavabit.com>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

pkgbase=virtualbox-libre-modules
pkgname=('virtualbox-libre-host-modules' 'virtualbox-libre-guest-modules')
pkgver=4.2.12
pkgrel=5
arch=('i686' 'x86_64')
url='http://virtualbox.org'
license=('GPL')
makedepends=('linux-libre'
             'linux-libre-headers'
             "virtualbox-libre-host-dkms>=$pkgver"
             "virtualbox-libre-guest-dkms>=$pkgver"
             'expac'
             'sed'
             'bc')

build() {
  _kernmaj=$(expac -Q '%v' linux-libre|sed -r 's/([[:digit:]]+\.[[:digit:]]+).*/\1/')
  _kernver=$(< /usr/lib/modules/extramodules-$_kernmaj-LIBRE/version)
  # dkms need modification to be run as user
  cp -r /var/lib/dkms .
  echo "dkms_tree='$srcdir/dkms'" > dkms.conf
  # build host modules
  msg2 'Host modules'
  dkms --dkmsframework dkms.conf build "vboxhost/$pkgver" -k "$_kernver"
  # build guest modules
  msg2 'Guest modules'
  dkms --dkmsframework dkms.conf build "vboxguest/$pkgver" -k "$_kernver"
}

package_virtualbox-libre-host-modules(){
  _kernmaj=$(expac -Q '%v' linux-libre|sed -r 's/([[:digit:]]+\.[[:digit:]]+).*/\1/')
  _kernver=$(< /usr/lib/modules/extramodules-$_kernmaj-LIBRE/version)
  pkgdesc='Host kernel modules for VirtualBox (built for the linux-libre kernel package)'
  #depends=("linux-libre>=$_kernmaj" "linux-libre<$(echo "$_kernmaj+0.1"|bc)")
  depends=('linux-libre>=3.9' 'linux-libre<3.10')
  provides=("virtualbox-host-modules=${pkgver}")
  replaces=('virtualbox-host-modules' 'virtualbox-modules' 'virtualbox-libre-modules')
  conflicts=('virtualbox-host-modules' 'virtualbox-modules' 'virtualbox-libre-modules')
  install=virtualbox-libre-host-modules.install

  cd "dkms/vboxhost/$pkgver/$_kernver/$CARCH/module"
  install -dm755 "$pkgdir/usr/lib/modules/extramodules-$_kernmaj-LIBRE/"
  install -m644 * "$pkgdir/usr/lib/modules/extramodules-$_kernmaj-LIBRE/"
  find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
  sed -ie "s/VERSION='.*'/VERSION='$_kernver'/" "$startdir/virtualbox-libre-host-modules.install"
}

package_virtualbox-libre-guest-modules(){
  _kernmaj=$(expac -Q '%v' linux-libre|sed -r 's/([[:digit:]]+\.[[:digit:]]+).*/\1/')
  _kernver=$(< /usr/lib/modules/extramodules-$_kernmaj-LIBRE/version)
  pkgdesc='Guest kernel modules for VirtualBox (built for the linux-libre kernel package)'
  license=('GPL')
  #depends=("linux-libre>=$_kernmaj" "linux-libre<$(echo "$_kernmaj+0.1"|bc)")
  depends=('linux-libre>=3.9' 'linux-libre<3.10')
  provides=("virtualbox-guest-modules=${pkgver}")
  replaces=('virtualbox-guest-modules' 'virtualbox-archlinux-modules' 'virtualbox-parabola-modules')
  conflicts=('virtualbox-guest-modules' 'virtualbox-archlinux-modules' 'virtualbox-parabola-modules')
  install=virtualbox-libre-guest-modules.install

  cd "dkms/vboxguest/$pkgver/$_kernver/$CARCH/module"
  install -dm755 "$pkgdir/usr/lib/modules/extramodules-$_kernmaj-LIBRE/"
  install -m644 * "$pkgdir/usr/lib/modules/extramodules-$_kernmaj-LIBRE/"
  find "$pkgdir" -name '*.ko' -exec gzip -9 {} +
  sed -ie "s/VERSION='.*'/VERSION='$_kernver'/" "$startdir/virtualbox-libre-guest-modules.install"
}

# vim:set ts=2 sw=2 et: