#Maintainer: Xyne <ac xunilhcra enyx, backwards>
#Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
pkgname=reflector
pkgver=2014
pkgrel=2
pkgdesc='A Python 3 module and script to retrieve and filter the latest Pacman mirror list (Parabola rebranded)'
arch=(any)
license=(GPL)
url="http://xyne.archlinux.ca/projects/reflector"
depends=(python3)
optdepends=('rsync: rate rsync mirrors')
source=(
  https://repo.parabolagnulinux.org/sources/reflector-2014.tar.xz
  https://repo.parabolagnulinux.org/sources/reflector-2014.tar.xz.sig
)
sha512sums=(
  2783c578c4a29b1e7db1320a7f2e259e104dacab2bcc9cfddcea91335cbb89b282e1d3f03919f9760a3c431ba0d358b4f54fd5bab72488cf74e0e2cd73fc6ba2
  SKIP
)
md5sums=(
  9b6ec85b8be7f9c4f8b68d00274b0cde
  SKIP
)
mksource=(
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2014.tar.xz
  http://xyne.archlinux.ca/projects/reflector/src/reflector-2014.tar.xz.sig
  rebranding.patch
)
mksha512sums=(
  ac9e0026019048c96be5dd4d156bf79b7d7616f764b5d8fb169cb09cbf629a3e2b1efb1ee7cb53b4e0cd109b985f598d9f80941714e47ed0f21c6417df9b073b
  SKIP
  83609177f88c0412f1a543f0431ecfb8be229bfef76d7087c35e9273988faedaf24a98ca45d98248eb5dfaa9a27e321dea99a256c68c5bc86a8a0ba53ed56d02
)
mkmd5sums=(
  69ab92b948ffe842189229d09bfbf1c0
  SKIP
  24c2a21bc1ac0d3758d8043f36d95add
)

mksource ()
{
  cd "$srcdir/$pkgname-$pkgver"
  # Rebranding for Parabola
  patch -Np1 -i "$srcdir/rebranding.patch"
}

package ()
{
  cd "$srcdir/$pkgname-$pkgver"
  python3 setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  install -Dm755 "$srcdir/$pkgname-$pkgver/$pkgname" "$pkgdir/usr/bin/$pkgname"
}


# vim: set ts=2 sw=2 et: