# $Id: PKGBUILD 111581 2014-05-20 17:25:40Z speps $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Maintainer: speps <speps at aur dot archlinux dot org>
# Contributor: Max Pray a.k.a. Synthead <synthead@gmail.com>
# Contributor: clarence <catchfire at gmail dot com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=patchage
_pkgname=patchage-libre
pkgver=1.0.0
pkgrel=2.parabola1
pkgdesc="A modular patch bay for audio and MIDI systems based on Jack and Alsa, with unpacked Waf in source tarball"
arch=('i686' 'x86_64')
url="http://drobilla.net/software/patchage"
license=('GPL3')
depends=('ganv' 'jack' 'desktop-file-utils')
makedepends=('boost' 'python2')
install="$pkgname.install"
mksource=("http://download.drobilla.net/$pkgname-$pkgver.tar.bz2")
source=("https://repo.parabola.nu/other/$_pkgname/$_pkgname-$pkgver.tar.bz2")
mkmd5sums=('d16a3fc045faff7fd70f3b4769b65698')
md5sums=('dcf5d06b90fcd9af2f384f6233907473')

mksource() {
  # generate an unpacked instance of the Waf all-in-one blob
  # based on:
  # https://wiki.debian.org/UnpackWaf
  # https://sources.debian.net/src/patchage/1.0.0~dfsg0-0.1/debian/unpack_waf.sh

  msg "Unpacking Waf... "
  cd $pkgname-$pkgver
  python2 waf --help &>/dev/null
  WAFDIR=`ls .waf-*/`
  mv .waf-*/$WAFDIR $WAFDIR
  sed -i '/^#==>$/,$d' waf
  rmdir .waf-*
  msg "OK"

  msg "Purging .pyc files... "
  find $WAFDIR -name "*.pyc" -delete
  msg "OK"
}

prepare() {
  cd $pkgname-$pkgver

  # FS#40311
  # disable jack metadata support for jack2 capability
  sed -i '/jack_get_property/,/False/d' wscript
}

build() {
  cd $pkgname-$pkgver
  python2 waf configure --prefix=/usr
  python2 waf build $MAKEFLAGS
}

package() {
  cd $pkgname-$pkgver
  python2 waf install --destdir="$pkgdir"
}

# vim:set ts=2 sw=2 et: