# $Id: PKGBUILD 203246 2014-01-06 19:32:24Z bpiotrowski $
# Contributor (Arch): Thayer Williams <thayer@archlinux.org>
# Contributor (Arch): Hugo Doria <hugo@archlinux.org>
# Contributor (Arch): TuxSpirit<tuxspirit@archlinux.fr>  2007/11/17 21:22:36 UTC
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer (Arch): Gaetan Bisson <bisson@archlinux.org>

_pkgname=p7zip-libre
pkgname=p7zip
pkgver=9.20.1
pkgrel=9.parabola1
pkgdesc='Command-line version of the 7zip compressed file archiver, without nonfree decompression engine for RAR archives'
url='http://p7zip.sourceforge.net/'
license=('GPL')
arch=('i686' 'x86_64' 'mips64el')
conflicts=('p7zip-libre')
replaces=('p7zip-libre')
depends=('gcc-libs' 'bash')
optdepends=('wxgtk2.8: GUI'
            'desktop-file-utils: desktop entries')
makedepends=('yasm' 'nasm' 'wxgtk2.8')
mksource=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}_${pkgver}_src_all.tar.bz2")
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}_${pkgver}_src_all.tar.bz2"
        '7zFM.desktop' 'libre.patch')
mksha1sums=('1cd567e043ee054bf08244ce15f32cb3258306b7')
sha1sums=('4e5ba097a90f3e00ad072023030c87f0707733b8'
          'f2c370d6f1b286b7ce9a2804e22541b755616a40'
          'bd929fdcbc05dcc783f7fa7d156ed15d38b0b4b3')

options=('!makeflags')
install=install

mksource() {
	cd "${srcdir}/${pkgname}_${pkgver}"

	# Remove nonfree unRAR utility files from the source
	rm -rv CPP/7zip/{Archive,Compress}/Rar
	rm -v CPP/7zip/Compress/{Rar{2,3}Decoder.{cpp,h},Rar3Vm.{cpp,h},RarCodecsRegister.cpp}
	rm -v CPP/7zip/Crypto/{Rar20Crypto,RarAes}.{cpp,h}
	rm -v DOCS/unRarLicense.txt

	# Remove nonfree parent folder icon
	rm CPP/7zip/UI/FileManager/res/ParentFolder.h
}

prepare() {
	cd "${srcdir}/${pkgname}_${pkgver}"

	# remove rar and parent folder icon references
	patch -Np1 -i ../libre.patch

	rm GUI/kde4/p7zip_compress.desktop
	[[ $CARCH = x86_64 ]] \
	&& cp makefile.linux_amd64_asm makefile.machine \
	|| cp makefile.linux_x86_asm_gcc_4.X makefile.machine

	sed -i 's/wx-config/wx-config-2.8/g' CPP/7zip/TEST/TestUI/makefile \
		CPP/7zip/UI/{FileManager,GUI,P7ZIP}/makefile
}

build() {
	cd "${srcdir}/${pkgname}_${pkgver}"
	make all4 OPTFLAGS="${CXXFLAGS}"
}

package() {
	cd "${srcdir}/${pkgname}_${pkgver}"
	make install \
		DEST_DIR="${pkgdir}" \
		DEST_HOME="/usr" \
		DEST_MAN="/usr/share/man"

	# Licenses
	install -d "${pkgdir}"/usr/share/licenses/p7zip
	ln -s -t "${pkgdir}"/usr/share/licenses/p7zip \
		/usr/share/doc/p7zip/DOCS/License.txt

	# Integration with stuff...
	install -Dm644 GUI/p7zip_32.png "${pkgdir}"/usr/share/icons/hicolor/32x32/apps/p7zip.png
	install -d "${pkgdir}"/usr/share/{applications,kde4/services/ServiceMenus}
	cp GUI/kde4/* "${pkgdir}"/usr/share/kde4/services/ServiceMenus/
	cp ../7zFM.desktop "${pkgdir}"/usr/share/applications/
	ln -s 7zCon.sfx "${pkgdir}"/usr/lib/p7zip/7z.sfx

	find GUI/help -type d -exec chmod 755 {} \;
	cp -r GUI/help "${pkgdir}"/usr/lib/p7zip/

	chmod -R u+w "${pkgdir}/usr"
}