# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=opencollada
pkgver=20140214
pkgrel=1.parabola1
pkgdesc="Stream based reader and writer library for COLLADA files (built for the blender package)"
arch=('i686' 'x86_64' 'mips64el')
url='https://github.com/KhronosGroup/OpenCOLLADA'
license=('GPL')
depends=('libxml2' 'pcre')
makedepends=('git' 'cmake')
conflicts=("$pkgname-parabola")
replaces=("$pkgname-parabola")
source=('git://github.com/KhronosGroup/OpenCOLLADA.git')
md5sums=('SKIP')

prepare() {
  cd $srcdir/OpenCOLLADA

  # adapt source to last blender release
  git reset --hard 8dc9e4e5b73caa1fcfe19508f381a087e036d886 # Fri Feb 14 14:32:18 2014 -0800
}

build() {
  cd "$srcdir"/OpenCOLLADA

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_SHARED=ON \
    -DUSE_STATIC=OFF
  make
}

package() {
  cd $srcdir/OpenCOLLADA/build

  make DESTDIR=$pkgdir install

  install -d $pkgdir/etc/ld.so.conf.d
  echo /usr/lib/$pkgname > $pkgdir/etc/ld.so.conf.d/$pkgname.conf
}

# vim:set ts=2 sw=2 et: