# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
pkgver=10.2.7
pkgrel=3
pkgdesc='Mesa 3-D OpenCL library and ICD loader'
arch=('i686' 'x86_64' 'mips64el')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase=$pkgver" 'libclc' 'clang')


makedepends=('dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2')
provides=("$_pkgname")
conflicts=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
replaces=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
source=("ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2"
        "llvm35.patch")
sha512sums=('c6d346499ef9596d3b5cd0bdc0ec64b58e8170203e0c977c54b55652c8792beb471822c101461745f7228a7d15a43924211f56fc0cc989defdc1acc4ea7b8a71'
            'dbf6792c94c80e067f3d1a33237ca1e28be7069a366c46b36997afab97c8a712758b07dc7f9fce0b3e20b8280d41539f02d70ee5c7e16188d8f6db9731fb6881')

prepare() {
  cd $srcdir/${pkgbase^}-$pkgver

  patch -Np1 -i ../llvm35.patch
}

build() {
  cd $srcdir/${pkgbase^}-$pkgver

  autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --enable-llvm-shared-libs \
    --enable-opencl \
    --with-clang-libdir=/usr/lib
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver

  install -vm755 -d $pkgdir/usr/lib/
  mv -v $srcdir/fakeinstall/usr/lib/libOpenCL* $pkgdir/usr/lib/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: