# Maintainer: Márcio Silva <coadde@lavabit.com>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
_pkgflag=libre
pkgver=10.0.1
pkgrel=2
pkgdesc='Mesa 3-D OpenCL library'
url=http://${pkgbase}3d.sourceforge.net
license=(MIT Khronos LGPL)
arch=(mips64el x86_64 i686)
depends=(
  libclc
  $pkgbase
)
optdepends='opencl-headers: headers necessary for OpenCL development'
makedepends=(
  clang
  dri2proto
  glproto
  imake
  libxml2
  python2
)
provides=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
conflicts=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
replaces=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
source=(
  ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2
  revert.remove.GLXContextID.typedef.patch
)
sha512sums=(
  7abdc38cb5b8b09bd586e6045b1d67cb809951f467d67a95e866d49b972c0c56d6a5b8612c411580bf59759a7ce49992eaf4dcc1c16aa1d67513f16b869bdfc1
  a2a92d997e1615548371ef618daf47011c7fc71d51d31dbdf47a54d56e078f98af624bde5cd7779c3d8ffb60f3b64aa8ebb5d6363cad261e52605926b47d7a35
)

prepare() {
  cd $srcdir/${pkgbase^}-$pkgver

  # Cherry picked from mesa branch 10.0, this fix wxgtk rebuild (FS#38392)
  patch -Np1 -i ../revert.remove.GLXContextID.typedef.patch
}

build() {
  cd $srcdir/${pkgbase^}-$pkgver
  autoreconf -vfi
  ./configure --prefix=/usr\
    --enable-opencl\
    --enable-gallium-llvm\
    --enable-r600-llvm-compiler\
    --with-clang-libdir=/usr/lib\
    --with-llvm-shared-libs\
    --with-gallium-drivers=i915,nouveau,r300,r600,radeonsi,svga,swrast
  make V=0
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver
  make -C src/gallium/targets/opencl DESTDIR=$pkgdir install
  install -vdm755 $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}