# Maintainer (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_ver=1.12
pkgname=mate-icon-theme-faenza
pkgver=${_ver}.0
pkgrel=1.parabola1
pkgdesc="Faenza icon theme for MATE, without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('LGPL')
depends=('gtk-update-icon-cache')
makedepends=('git' 'icon-naming-utils' 'mate-common')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
options=(!strip)
groups=('mate-extra' 'mate-extra-gtk3')
source=("http://pub.mate-desktop.org/releases/${_ver}/${pkgname}-${pkgver}.tar.xz")
sha1sums=('391bb5c04a3090feeac4b92850ce57b96ebd53c2')
install=${pkgname}.install

prepare() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    NOCONFIGURE=1 ./autogen.sh
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype playonlinux picasa spotify; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"
    make DESTDIR="${pkgdir}" install
    rm -f "${pkgdir}/usr/share/icons/matefaenza/icon-theme.cache"
}