# Maintainer (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=mate-icon-theme-faenza
pkgname=mate-icon-theme-faenza-libre
pkgver=1.8.0
pkgrel=1.1
pkgdesc="Faenza icon theme for MATE, without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('LGPL')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
depends=('hicolor-icon-theme' 'gtk-update-icon-cache')
makedepends=('icon-naming-utils' 'mate-common')
options=(!strip)
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.8/${_pkgname}-${pkgver}.tar.xz")
sha1sums=('60ecb21261d969e60925254cb435a4a877540d4c')
install=${_pkgname}.install

prepare() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    make DESTDIR="${pkgdir}" install
    rm -f "${pkgdir}/usr/share/icons/matefaenza/icon-theme.cache"
}