# Maintainer : Martin Wimpress <code@flexion.org>

_pkgname=mate-file-archiver
pkgname=mate-file-archiver-libre
pkgver=1.6.2
pkgrel=1
pkgdesc="Archive manipulator for MATE, with unar recommendation included and nonfree unace recommendation removed"
url="http://mate-desktop.org"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
depends=('bzip2' 'desktop-file-utils' 'gtk2' 'gzip' 'libarchive'
         'mate-file-manager' 'tar')
makedepends=('mate-common' 'mate-doc-utils' 'perl-xml-parser')
optdepends=('arj: for ARJ support'
            'p7zip: for 7zip support'
            'unar: for RAR extract support'
            'unzip: for ZIP extract support'
            'zip: for ZIP support')
options=('!emptydirs')
groups=('mate-extra')
source=("http://pub.mate-desktop.org/releases/1.6/${_pkgname}-${pkgver}.tar.xz"
        fr-rpm-bsdtar.patch)
sha1sums=('58a0f7d78dabd627a3a2b3352fabcba20d72aa92'
          '219b05a979bf6f249aaae27964f02345fd81168d')
install=${_pkgname}.install

prepare() {
    cd "${srcdir}/${_pkgname}-${pkgver}"    
    # This patch 'depends' on libarchive
    patch -Np1 -i "${srcdir}/fr-rpm-bsdtar.patch"
}

build() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${_pkgname} \
        --disable-static \
        --disable-scrollkeeper \
        --disable-packagekit
    mate-doc-prepare --force
    make
}

package() {
    cd "${srcdir}/${_pkgname}-${pkgver}"
    make DESTDIR="${pkgdir}" install
}