# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Maintainer (Parabola): Márcio Silva <coadde@adinet.com.uy>
_pkgname=luxrays
pkgname=luxrays-libre
pkgver=0.8
_pkgver=ed424ec77571
pkgrel=7
epoch=0
pkgdesc="Accelerate the ray intersection process by using CPUs (without OpenCL)"
arch=('i686' 'x86_64')
url="http://www.luxrender.net/"
license=('GPL')
depends=('freeimage' 'freeglut' 'glew')
makedepends=('cmake' 'boost')
replaces=('luxrays')
conflicts=('luxrays')
provides=("luxrays=$pkgver")
source=(https://bitbucket.org/luxrender/luxrays/get/$_pkgver.tar.bz2)
md5sums=('2ac9c588675c5971c57f473ef10ac67d')

build() {
  cd "$srcdir/luxrender-$_pkgname-$_pkgver"

  # fix the break caused by the change of the name of the namespace 'detail' to 'ipcdetail'
  sed -i 's|::detail|::ipcdetail|' include/luxrays/utils/core/atomic.h

  export CXXFLAGS="$CXXFLAGS -lpthread"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DLUXRAYS_DISABLE_OPENCL=ON \
    .
  make
}

package() {
  cd "$srcdir/luxrender-$_pkgname-$_pkgver"

  install -d -m755 "$pkgdir"/usr/{bin,include,lib}
  install -m755 bin/* "$pkgdir"/usr/bin
  install -m644 lib/* "$pkgdir"/usr/lib
  cp -a include/luxrays "$pkgdir"/usr/include
}

# vim:set ts=2 sw=2 et: